# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-mail/mlmmj/mlmmj-1.2.9.ebuild,v 1.1 2005/12/15 08:44:35 lcars Exp $

inherit eutils webapp

MY_PV="${PV/_rc/-RC}"
MY_P="${PN}-${MY_PV}"
DESCRIPTION="Mailing list managing made joyful"
HOMEPAGE="http://mlmmj.mmj.dk/"
SRC_URI="http://mlmmj.mmj.dk/files/${MY_P}.tar.bz2"
LICENSE="MIT"
WEBAPP_MANUAL_SLOT="yes"
SLOT="0"
KEYWORDS="~x86 ~ppc ~ppc-macos ~amd64"
IUSE="php-user php-admin perl-user perl-admin"
DEPEND="virtual/mta"
RDEPEND="php-user? ( virtual/php )
		php-admin? ( virtual/php )
		perl-admin? ( dev-perl/CGI-FastTemplate )"
S="${WORKDIR}/${MY_P}"
SHAREDIR="/usr/share/mlmmj"

pkg_setup() {
	webapp_pkg_setup
	if ( use php-user && use perl-user ); then
		die "Please select only one of php-user and perl-user"
	fi
	if ( use php-admin && use perl-admin ); then
		die "Please select only one of php-admin and perl-admin"
	fi
}

src_compile() {
	econf
	emake || die
}

src_install() {
	webapp_src_preinst
	make DESTDIR=${D} install || die

	dodir ${SHAREDIR}
	dodir ${SHAREDIR}/texts
	insinto ${SHAREDIR}/texts
	doins listtexts/*

	dodoc AUTHORS ChangeLog COPYING FAQ LICENSE README
	dodoc TODO TUNABLES UPGRADE VERSION README.access
	dodoc README.sendmail README.exim4 README.security
	touch ${T}/README

	if use php-user; then
		cp ${S}/contrib/web/php-user/[em]* ${D}/${MY_HTDOCSDIR}
		cat ${S}/contrib/web/php-user/README >> ${T}/README
	fi
	if use php-admin; then
		dodir ${MY_HOSTROOTDIR}/${PN}
		cp ${S}/contrib/web/php-admin/htdocs/* ${D}/${MY_HTDOCSDIR}
		cp -R ${S}/contrib/web/php-admin/{conf,templates} ${D}/${MY_HOSTROOTDIR}/${PN}
		cat ${S}/contrib/web/php-admin/README >> ${T}/README
		webapp_hook_script ${FILESDIR}/reconfig-php-admin
	fi
	if use perl-user; then
		cp ${S}/contrib/web/perl-user/* ${D}/${MY_HTDOCSDIR}
	fi
	if use perl-admin; then
		dodir ${MY_HOSTROOTDIR}/${PN}
		cp ${S}/contrib/web/perl-admin/htdocs/* ${D}/${MY_HTDOCSDIR}
		cp -R ${S}/contrib/web/perl-admin/{conf,templates} ${D}/${MY_HOSTROOTDIR}/${PN}
		cat ${S}/contrib/web/perl-admin/README >> ${T}/README
		webapp_hook_script ${FILESDIR}/reconfig-perl-admin
	fi
	webapp_postinst_txt en ${T}/README
	webapp_src_install
}