reminiscence-0.1.8.ebuild

reminiscence-0.1.8.ebuild (text/plain), 1.19 KB, created by Adrian Frühwirth on 2006-01-30 16:23:55 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils toolchain-funcs games

MY_PN=REminiscence
MY_P=${MY_PN}-${PV}

DESCRIPTION="Reimplementation of the Flashback engine using SDL"
HOMEPAGE="http://membres.lycos.fr/cyxdown/reminiscence"
SRC_URI="http://membres.lycos.fr/cyxdown/${PN}/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

DEPEND="sys-libs/zlib
	media-libs/libsdl"

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch ${FILESDIR}/${PN}-homedir-fix.patch

	sed -i \
		-e "s:DATA:${GAMES_DATADIR}/${PN}:g" \
		main.cpp \
		|| die "sed failed"
}

src_compile() {
	emake \
		CXX=$(tc-getCXX) \
		CXXFLAGS="${CXXFLAGS} \$(SDL_CFLAGS) \$(DEFINES)" \
		|| die "emake failed"
}

src_install() {
	dodir ${GAMES_DATADIR}/${PN} || die "dodir failed"
	newgamesbin rs reminiscence || die "newgamesbin failed"
	dodoc README TODO
	prepgamesdirs
}

pkg_postinst() { 
	echo
	einfo "To play the game, copy the contents of the PC version's"
	einfo "DATA directory of the original game into ${GAMES_DATADIR}/${PN}."
	einfo "For sound to work you need the Amiga version's .mod files."
	games_pkg_postinst
}