# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils versionator games

MY_PV=$(replace_version_separator 2 '-')
MY_PV=${MY_PV/_beta/dev}
MY_PV=${MY_PV/_rc/rc}

DESCRIPTION="Elite space trading & warfare remake"
HOMEPAGE="http://oolite.aegidian.org/"
FILE="oolite-${MY_PV}.x86.tar.gz"
SRC_URI="ftp://ftp.alioth.net/oolite/${FILE}
	http://download.berlios.de/oolite-linux/${FILE}"

# See /opt/Oolite/doc/LICENSE.TXT
LICENSE="creativecommons-by-nc-sa-2.0"

SLOT="0"
KEYWORDS="~x86"
IUSE=""

RDEPEND="
	>=dev-libs/DirectFB-0.9.22
	>=media-libs/jpeg-6b-r5
	>=media-libs/libogg-1.1.2
	>=media-libs/libpng-1.2.8
	>=media-libs/libsdl-1.2.8-r1
	>=media-libs/libvorbis-1.1.0
	>=media-libs/sdl-gfx-2.0.13-r1
	>=media-libs/sdl-image-1.2.3-r1
	>=media-libs/sdl-mixer-1.2.6
	>=media-libs/tiff-3.7.3
	virtual/opengl
	|| (
		(
			media-libs/mesa
			x11-libs/libX11
			x11-libs/libXau
			x11-libs/libXdmcp
			x11-libs/libXext )
		virtual/x11 )"
DEPEND=""

S=${WORKDIR}/oolite-installer
dir=${GAMES_PREFIX_OPT}/Oolite

src_install() {
	sed -i install \
		-e "s:/usr/local:${D}opt:" \
		-e "s:\$INSTALLDIR/bin:${D}${GAMES_PREFIX_OPT}/\$TOPLEVEL/bin:" \
		-e "s:OOLITE_ROOT=\$INSTALLDIR:OOLITE_ROOT=${GAMES_PREFIX_OPT}:" \
		|| die "sed failed"

	dodir "${dir}"/bin
	./install systemwide || die "install failed"

	# Remove updater program
	rm "${D}/${dir}"/bin/oolite-update

	# Remove unnecessary libraries which revdep-rebuild would moan about
	rm -rf "${D}/${dir}"/oolite-deps/GNUstep/System/Library/Bundles/{GSPrinting,SSL.bundle}

	# Use wrapper for pre-compiled binary
	games_make_wrapper oolite "${dir}"/bin/oolite

	prepgamesdirs
}