e-uae-0.8.28.ebuild

e-uae-0.8.28.ebuild (text/plain), 1.67 KB, created by Paul Bredbury on 2006-01-27 04:09:07 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils flag-o-matic

DESCRIPTION="The Eggplant Ubiquitous Amiga Emulator"
HOMEPAGE="http://www.rcdrummond.net/uae/"
SRC_URI="http://www.rcdrummond.net/uae/${P}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="X gtk sdl ncurses svga"

DEPEND="virtual/libc
	X? ( || (
			(
			x11-proto/xf86vidmodeproto
			x11-proto/xf86dgaproto
			x11-libs/libXt
			x11-libs/libxkbfile
			)
			virtual/x11
		)
		gtk? ( >=x11-libs/gtk+-2.0.0 )
	)
	!X? (
		ncurses? ( sys-libs/ncurses )
		svga? ( media-libs/svgalib )
	)
	sdl? ( media-libs/libsdl )
	app-cdr/cdrtools
	games-emulation/caps"

src_compile() {
	local myconf=""

	# -O3 breaks compilation, GCC will eat all your RAM + Swap and die
	replace-flags "-O3" "-O2"
	use x86 && strip-flags "-msse" "-msse2"
	use ppc && strip-flags "-maltivec" "-mabi=altivec"
	use sdl && myconf="--with-sdl-sound --with-sdl-gfx"

	export WANT_AUTOMAKE=1.7
	export WANT_AUTOCONF=2.5

	./bootstrap.sh || die "bootstrap failed"

	econf ${myconf} \
		--enable-threads \
		--enable-cdtv \
		--enable-cd32 \
		--enable-scsi-device \
		--enable-bsdsock-new \
		--with-libscg-includedir=/usr/include/scsilib \
		|| die "econf failed"

	emake || die "emake failed"
}

src_install() {
	dodoc docs/*
	dodoc README COPYING ChangeLog CHANGES

	emake install DESTDIR=${D}

	insinto /usr/share/uae/amiga-tools
	doins amiga/{*hack,trans*,uae*,*.library}

	# Rename executables, to prevent conflict with uae ebuild
	mv ${D}/usr/bin/uae ${D}/usr/bin/e-uae
	mv ${D}/usr/bin/readdisk ${D}/usr/bin/e-readdisk
	mv ${D}/usr/share/uae ${D}/usr/share/${PN}
}