bzr-0.6.2.ebuild

bzr-0.6.2.ebuild (text/plain), 1.06 KB, created by Christian Schlotter on 2006-01-27 01:52:44 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit distutils elisp-common

PYTHON_MODNAME="bzrlib"
DESCRIPTION="next generation distributed version control"
HOMEPAGE="http://bazaar-ng.org/"
SRC_URI="http://bazaar-ng.org/pkg/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="emacs"
DEPEND=">=dev-lang/python-2.4
	dev-python/elementtree
	emacs? ( virtual/emacs )"

src_compile() {
	distutils_src_compile
	if use emacs; then
		einfo "Compiling Emacs support..."
		elisp-compile ${S}/contrib/emacs/bzr-mode.el || die "Emacs modules failed!"
	fi
}

src_install() {
	distutils_src_install
	if use emacs; then
		insinto /usr/share/emacs/site-lisp
		doins contrib/emacs/bzr-mode.el*
		elisp-site-file-install ${FILESDIR}/70bzr-gentoo.el
	fi
}

pkg_postinst() {
	distutils_pkg_postinst
	use emacs && elisp-site-regen
	einfo "You may optionally \033[1memerge dev-python/celementtree\033[0m for faster processing."
}

pkg_postrm() {
	distutils_pkg_postrm
	has_version virtual/emacs && elisp-site-regen
}