ulogd-1.23.ebuild (update)

ulogd-1.23.ebuild (text/plain), 1.45 KB, created by Torben Janssen on 2006-01-21 08:17:04 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/ulogd/ulogd-1.02-r1.ebuild,v 1.3 2005/02/03 06:48:00 eradicator Exp $

inherit flag-o-matic

DESCRIPTION="iptables daemon for ULOG target for userspace iptables filter logging"
SRC_URI="http://ftp.netfilter.org/pub/ulogd/${P}.tar.bz2"
HOMEPAGE="http://www.netfilter.org/projects/ulogd/index.html"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~x86"
IUSE="mysql postgres sqlite3"

DEPEND="net-firewall/iptables
	net-libs/libpcap
	mysql? ( dev-db/mysql )
	postgres? ( dev-db/postgresql )
	sqlite3? ( dev-db/sqlite )"

src_compile() {
	# enables logfiles over 2G (#74924)
	append-flags -D_FILE_OFFSET_BITS=64

	econf \
		`use_with mysql` \
		`use_with postgres pgsql` \
		`use_with sqlite3` \
		|| die "configure failed"
	make || die "make failed"
}

src_install() {
	# the Makefile seems to be "broken" -
	# it relies on the existance of /usr, /etc ..
	dodir /usr/sbin

	make DESTDIR=${D} install || die "install failed"

	doman ulogd.8

	exeinto /etc/init.d/
	newexe ${FILESDIR}/ulogd-0.98 ulogd

	insinto /etc
	doins ulogd.conf

	insinto /etc/logrotate.d
	newins ulogd.logrotate ulogd

	dodoc README AUTHORS Changes
	cd doc/
	dodoc ulogd.txt ulogd.a4.ps

	if use mysql; then
		dodoc mysql.table mysql.table.ipaddr-as-string
	fi

	if use postgres; then
		dodoc pgsql.table
	fi

	if use sqlite3; then
		dodoc sqlite3.table
	fi

	dohtml ulogd.html
}