keytouch-2.1.0_beta1.ebuild

keytouch-2.1.0_beta1.ebuild (text/plain), 2.11 KB, created by Tristan Heaven (RETIRED) on 2006-01-20 07:08:37 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils versionator

# Fixes for beta version
MY_PV=${PV/_beta*/-beta}
MY_P=${PN}-${MY_PV}

DESCRIPTION="Easily configure extra keyboard function keys."
HOMEPAGE="http://keytouch.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="kde"

RDEPEND=">=x11-libs/gtk+-2
		x11-misc/xbindkeys
		kde? ( || ( kde-base/kdebase
				kde-base/kdesu ) )
		!kde? ( x11-libs/gksu )"

# Unpacked dir doesn't include the full version number
#S=${WORKDIR}/${PN}-$(get_version_component_range 1-2)
S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${A}
	cd ${S}

	# Prevent sandbox violations
	sed -i -e 's/install-data-local//' \
		keytouchd/Makefile.in \
		keytouch-init/Makefile.in \
		keytouch-acpid/Makefile.in \
		|| die "sed (install-data-local) failed"
}

src_compile() {
	econf || die "econf failed"
	emake || die "emake failed"

	cd ${S}/keytouch-config
	econf || die "econf (keytouch-config) failed"
	emake || die "emake (keytouch-config) failed"

	cd ${S}/keytouch-keyboard
	econf || die "econf (keytouch-keyboard) failed"
	emake || die "emake (keytouch-keyboard) failed"
}

src_install() {
	make install DESTDIR="${D}" \
	|| die "make install failed"

	cd ${S}/keytouch-config
	make install DESTDIR="${D}" \
	|| die "make install (keytouch-config) failed"

	make_desktop_entry keytouch keyTouch keytouch.png System
	cp pixmaps/icon.png ${T}/keytouch.png
	doicon ${T}/keytouch.png

	cd ${S}/keytouch-keyboard
	make install DESTDIR="${D}" \
	|| die "make install (keytouch-keyboard) failed"

	doinitd ${FILESDIR}/keytouch
}

pkg_postinst() {
	einfo ""
	einfo "To make this work you need to add \"keytouchd &\""
	einfo "to your X startup programs and run"
	einfo "rc-update add keytouch default"
	einfo ""
	einfo "If support for your keyboard is not included in"
	einfo "this release, check for updated files here."
	einfo "http://keytouch.sourceforge.net/dl-keyboards.html"
	einfo ""
	einfo "x11-misc/keytouch-editor can be used to create"
	einfo "your own keyboard files."
	einfo ""
}