keytouch-2.0.1.ebuild

keytouch-2.0.1.ebuild (text/plain), 2.07 KB, created by Tristan Heaven (RETIRED) on 2006-01-16 06:27:05 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils versionator

DESCRIPTION="Easily configure extra keyboard function keys."
HOMEPAGE="http://keytouch.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="kde"

DEPEND=">=x11-libs/gtk+-2"
RDEPEND="${DEPEND}
		x11-misc/xbindkeys || (
		( x11-libs/gksu )
		kde? ( kde-base/kdelibs ) )" # kdesu is used if gksu isn't found

# Unpacked dir doesn't include the full version number
S=${WORKDIR}/${PN}-$(get_version_component_range 1-2)

src_unpack() {
	unpack ${A}
	cd ${S}

	# Prevent 'make install' writing to /etc/X11/ and /etc/init.d/
	sed -i -e 's/install-data-local//' \
		keytouchd/Makefile.in \
		keytouch-init/Makefile.in \
		|| die "sed (install-data-local) failed"
}

src_compile() {
	econf || die "econf failed"
	emake || die "emake failed"

	cd ${S}/keytouch-config
	econf || die "econf (keytouch-config) failed"
	emake || die "emake (keytouch-config) failed"

	cd ${S}/keytouch-keyboard
	econf || die "econf (keytouch-keyboard) failed"
	emake || die "emake (keytouch-keyboard) failed"
}

src_install() {
	make install DESTDIR="${D}" || die "make install failed"
	
	cd ${S}/keytouch-config
	make install DESTDIR="${D}" || die "make install (keytouch-config) failed"

	cd ${S}/keytouch-keyboard
	make install DESTDIR="${D}" || die "make install (keytouch-keyboard) failed"

	# Create menu entry
	mkdir ${D}/usr/share/pixmaps
	ln -s ${ROOT}/usr/share/keytouch/pixmaps/icon.png \
		${D}/usr/share/pixmaps/keytouch.png
	domenu ${FILESDIR}/keytouch.desktop

	# Init script
	doinitd ${FILESDIR}/keytouch
}

pkg_postinst() {
	einfo ""
	einfo "To make this work you need to add \"keytouchd &\""
	einfo "to your X startup programs."
	einfo ""
	einfo "If support for your keyboard is not included in"
	einfo "this release, check for updated files here."
	einfo "http://keytouch.sourceforge.net/dl-keyboards.html"
	einfo ""
	einfo "x11-misc/keytouch-editor can be used to create"
	einfo "your own keyboard files."
	einfo ""
}