ebuild with working module USE flag

libifp-1.0.0.2.ebuild (text/plain), 1.56 KB, created by Patrick McLean on 2006-01-15 21:32:20 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit linux-mod

IUSE="examples module"

DESCRIPTION="libifp is a general-purpose library-driver for iRiver's iFP (flash-based) portable audio players with optional kernel-module support"
HOMEPAGE="http://ifp-driver.sourceforge.net/libifp/"
SRC_URI="mirror://sourceforge/ifp-driver/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"

DEPEND=">=dev-libs/libusb-0.1.0
	>=app-doc/doxygen-1.3.7
	module? ( virtual/linux-sources )"
RDEPEND=">=dev-libs/libusb-0.1.0"

MODULE_NAMES="libifp(misc:${S}/kbuild)"

pkg_setup() {
	use module && linux-mod_pkg_setup
}

pkg_postrm() {
	use module && linux-mod_pkg_postrm
}

src_compile() {

	econf --with-libusb \
		$(use_enable examples) \
		$(use_with module kmodule) \
		|| die "configure failed"

	# don't compile the module here
	emake MAYBE_KBUILD="" || die "emake failed"

	if (use module); then
		BUILD_TARGETS="all"
		linux-mod_src_compile
	fi
}

src_install() {
	make install DESTDIR="${D}" || die "make install failed"

	if (use module); then
		linux-mod_src_install
	fi
	
	# clean /usr/bin after installation
	# by moving examples to proper dir
	if use examples; then
	    insinto /usr/share/${PN}/examples
	    doins ${S}/examples/simple.c ${S}/examples/ifpline.c
	    mv ${D}/usr/bin/{simple,ifpline} ${D}/usr/share/${PN}/examples
	else
	    rm -f ${D}/usr/bin/{simple,ifpline}
	fi

	dodoc README ChangeLog TODO
	# man pages aren't gziped
	prepallman
}

pkg_postinst() {
	use module && linux-mod_pkg_postinst
}