# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( python3_{8..10} )
inherit distutils-r1

# use the latest git version, release v21.1.0 does not build
#EGIT_REPO_URI="https://github.com/frescobaldi/python-poppler-qt5"
#EGIT_COMMIT="85adeddbc4658cd8b2daaaa067484ba9b46ad82c"
#inherit git-r3

DESCRIPTION="Python binding for libpoppler-qt5"
HOMEPAGE="https://github.com/frescobaldi/python-poppler-qt5"
SRC_URI="https://github.com/frescobaldi/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE=""

RDEPEND="
	app-text/poppler[qt5]
	dev-python/PyQt5[${PYTHON_USEDEP}]
	>=dev-python/sip-5:=[${PYTHON_USEDEP}]
"
DEPEND="${RDEPEND}"

PATCHES=(
	"${FILESDIR}"/${P}-unsupported-function-return-type.patch
)

python_compile() {
	# sip does not support separate build and installation
	# therefore install files to a subdir and copy in the installation phase
	sip-install --verbose --build-dir="${BUILD_DIR}" --target-dir="${BUILD_DIR}/target_dir/$(python_get_sitedir)"
}

python_install() {
	cp -r ${BUILD_DIR}/target_dir/* ${ED}
}