scribus-9999.ebuild

scribus-9999.ebuild (text/plain), 3.05 KB, created by cyrillic on 2022-03-10 22:43:20 UTC

# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7
EGIT_REPO_URI="https://github.com/scribusproject/${PN}.git"
PYTHON_COMPAT=( python3_{8..10} )
PYTHON_REQ_USE="tk?"
inherit desktop flag-o-matic git-r3 ninja-utils python-single-r1 xdg

DESCRIPTION="Desktop publishing (DTP) and layout program"
HOMEPAGE="https://www.scribus.net/"
SRC_URI=""

LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="boost debug examples graphicsmagick +minimal osg +pdf scripts +templates tk"

REQUIRED_USE="${PYTHON_REQUIRED_USE}
	tk? ( scripts )"

# osg
# couple of third_party libs bundled
BDEPEND="
	>=dev-qt/qttools-6.2.0:6=
	virtual/pkgconfig
"
DEPEND="${PYTHON_DEPS}
	app-text/libmspub
	app-text/libqxp
	app-text/poppler:=
	dev-libs/hyphen
	>=dev-libs/icu-58.2:0=
	dev-libs/librevenge
	dev-libs/libxml2
	>=dev-qt/qt5compat-6.2.0:6=
	>=dev-qt/qtbase-6.2.0:6=[cups,gui,network,opengl,widgets,xml]
	media-libs/fontconfig
	media-libs/freetype:2
	>=media-libs/harfbuzz-0.9.42:0=[icu]
	media-libs/lcms:2
	media-libs/libcdr
	media-libs/libfreehand
	media-libs/libpagemaker
	media-libs/libpng:0=
	media-libs/libvisio
	media-libs/libzmf
	media-libs/tiff:0
	net-print/cups
	sys-libs/zlib[minizip]
	virtual/jpeg:0=
	>=x11-libs/cairo-1.10.0[X,svg]
	boost? ( dev-libs/boost:= )
	graphicsmagick? ( media-gfx/graphicsmagick:= )
	app-text/hunspell:=
	osg? ( dev-games/openscenegraph:= )
	pdf? ( app-text/podofo:0= )
	scripts? (
		$(python_gen_cond_dep '
			dev-python/pillow[tk?,${PYTHON_USEDEP}]
		')
	)
"
RDEPEND="${DEPEND}
	app-text/ghostscript-gpl
"

BUILD_DIR=${WORKDIR}/${P}_build

src_prepare() {
	default_src_prepare
	mkdir -p "${BUILD_DIR}" || die
	einfo "Working in BUILD_DIR: \"$BUILD_DIR\""
}

src_configure() {
	xdg_environment_reset

	local mycmakeargs=(
		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
		-DWANT_RELOCATABLE=OFF
		-DWANT_PCH=OFF
		-DWANT_CCACHE=OFF
		-DWANT_DISTROBUILD=ON
		-DHAVE_PYTHON=ON
		-DWANT_CPP17=ON
		-DWANT_LIB64=ON
		-DDOCDIR="${EPREFIX}/usr/share/doc/${P}"
		-DPython3_EXECUTABLE="${PYTHON}"
		-DWITH_BOOST=$(usex boost)
		-DWANT_DEBUG=$(usex debug)
		-DWANT_RELEASEWITHDEBUG=$(usex !debug)
		-DWANT_NOEXAMPLES=$(usex !examples)
		-DWANT_GRAPHICSMAGICK=$(usex graphicsmagick)
		-DWANT_HEADERINSTALL=$(usex !minimal)
		-DWANT_NOOSG=$(usex !osg)
		-DWITH_PODOFO=$(usex pdf)
		-DWANT_NOTEMPLATES=$(usex !templates)
	)

	pushd "${BUILD_DIR}" > /dev/null || die
	cmake -G Ninja "${mycmakeargs[@]}" "${S}" || die "cmake failed"
	popd > /dev/null || die
}

src_compile() {
	pushd "${BUILD_DIR}" > /dev/null || die
	eninja "$@"
	popd > /dev/null || die
}

src_install() {
	pushd "${BUILD_DIR}" > /dev/null || die
	DESTDIR="${D}" ninja install "$@" || die "died running ninja install"
	popd > /dev/null || die

	pushd "${S}" > /dev/null || die
	einstalldocs
	popd > /dev/null || die

	if ! use tk; then
		rm "${ED}"/usr/share/scribus/scripts/{FontSample,CalendarWizard}.py || die
	fi
	if use scripts; then
		python_fix_shebang "${ED}"/usr/share/scribus/scripts
		python_optimize "${ED}"/usr/share/scribus/scripts
	else
		rm "${ED}"/usr/share/scribus/scripts/*.py || die
	fi
}