a7xpg-bin-0.110d.ebuild

a7xpg-bin-0.110d.ebuild (text/plain), 1.14 KB, created by Herval Ribeiro on 2006-01-08 18:53:55 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games

MY_PN="${PN/-bin/}"
MY_P="${MY_PN}-${PV}"
DESCRIPTION="Old school chase action game A7Xpg"
HOMEPAGE="http://www.asahi-net.or.jp/~cs8k-cyu/windows/a7xpg_e.html http://a7xpg.sourceforge.net/"
SRC_URI="mirror://sourceforge/${MY_PN}/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

RDEPEND="virtual/opengl
	virtual/glu
	media-libs/libsdl
	media-libs/sdl-mixer"

S="${WORKDIR}/${MY_PN}"

pkg_setup() {
	if ! built_with_use media-libs/sdl-mixer vorbis ; then
		eerror "${PN} will crash if sdl-mixer is"
		eerror "built without vorbis support"
		die "Please emerge sdl-mixer with USE=vorbis"
	fi
	games_pkg_setup
}

src_compile() {
	einfo "Nothing to compile"
}

src_install() {
	dogamesbin "${FILESDIR}/a7xpg" || die "dogamesbin failed"
	local dir="${GAMES_PREFIX_OPT}/${PN}"
	exeinto "${dir}"
	doexe a7xpg || die "doexe failed"
	insinto "${dir}"
	doins -r images sounds || die "doins failed"
	dodoc readme* || die "dodoc failed"
	doicon "${FILESDIR}/${PN}.png"
	make_desktop_entry "${MY_PN}" "A7Xpg"
	prepgamesdirs
}