Updated ebuild with lablgtk:3

unison-2.51.5.ebuild (text/plain), 2.73 KB, created by Bernd Feige on 2022-02-22 21:29:19 UTC

# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit desktop xdg-utils

DESCRIPTION="Two-way cross-platform file synchronizer"
HOMEPAGE="https://www.seas.upenn.edu/~bcpierce/unison/"
SRC_URI="https://github.com/bcpierce00/unison/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2"
SLOT="$(ver_cut 1-2)"
KEYWORDS="~amd64 ~arm ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris"
IUSE="debug doc gtk +ocamlopt threads"

BDEPEND="dev-lang/ocaml:=[ocamlopt?]
	doc? ( app-text/dvipsk
		app-text/ghostscript-gpl
		dev-texlive/texlive-latex )"
DEPEND="gtk? ( dev-ml/lablgtk:3=[ocamlopt?] )"
RDEPEND="gtk? ( dev-ml/lablgtk:3=[ocamlopt?]
	|| ( net-misc/x11-ssh-askpass net-misc/ssh-askpass-fullscreen ) )
	>=app-eselect/eselect-unison-0.4"

DOCS=( CONTRIB INSTALL NEWS README ROADMAP.txt TODO.txt )

PATCHES=(
	"${FILESDIR}"/62272e8f203f32510dfa292c99408928da974f4e.patch
	"${FILESDIR}"/393c03565399de3a8e02e105eb2b8ee8cc620f19.patch
	"${FILESDIR}"/9626711a6c6a4da4fb73fd6b81e1023710ee1266.patch
	"${FILESDIR}"/d0b45f073c0899d7e743582bdcad858bd2c69ea1.patch
	"${FILESDIR}"/e05957692b1e21517708e4252f3b0e22cb1ac206.patch
)

src_prepare() {
	default
	# https://github.com/bcpierce00/unison/issues/416
	sed -e "/ifdef\ HEVEA/,/endif/d" -i doc/Makefile || die
	# https://github.com/bcpierce00/unison/pull/415
	sed -e "/myName/d" -i doc/docs.ml || die
}

src_compile() {
	local myconf

	if use threads; then
		myconf+=( THREADS=true )
	fi

	if use debug; then
		myconf+=( DEBUGGING=true )
	fi

	if use gtk; then
		myconf+=( UISTYLE=gtk3 )
	else
		myconf+=( UISTYLE=text )
	fi

	use ocamlopt || myconf+=( NATIVE=false )

	if use doc; then
		VARTEXFONTS="${T}/fonts" emake "${myconf[@]}" CFLAGS="" HEVEA=false docs
	fi

	# Discard cflags as it will try to pass them to ocamlc...
	emake "${myconf[@]}" CFLAGS="" src
}

src_test() {
	emake test CFLAGS=""
}

src_install() {
	# install manually, since it's just too much
	# work to force the Makefile to do the right thing.
	local binname
	cd src || die
	for binname in unison unison-fsmonitor; do
		newbin ${binname} ${binname}-${SLOT}
	done

	if use gtk; then
		newicon -s scalable ../icons/U.svg ${PN}-${SLOT}.svg
		make_desktop_entry ${PN}-${SLOT} "${PN} (${SLOT})" "${PN}-${SLOT}"
	fi

	if use doc; then
		DOCS+=( ../doc/unison-manual.pdf )
		HTML_DOCS=( "${DISTDIR}/${P}-manual.html" )
	fi

	einstalldocs
}

pkg_postinst() {
	elog "Unison now uses SLOTs, so you can specify servercmd=/usr/bin/unison-${SLOT}"
	elog "in your profile files to access exactly this version over ssh."
	elog "Or you can use 'eselect unison' to set the version."
	eselect unison update || die

	if use gtk; then
		xdg_icon_cache_update
	fi
}

pkg_postrm() {
	if use gtk; then
		xdg_icon_cache_update
	fi
}