mpop 1.4.16 ebuild

mpop-1.4.16.ebuild (text/plain), 947 bytes, created by Herbert Wantesh on 2022-01-21 14:30:13 UTC

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

DESCRIPTION="A small, fast, and portable POP3 client"
HOMEPAGE="https://marlam.de/mpop/"
SRC_URI="https://marlam.de/mpop/releases/${P}.tar.xz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="amd64 ~arm ~x86"
IUSE="idn gnome-keyring nls sasl ssl vim-syntax"

RDEPEND="
	idn? ( net-dns/libidn2 )
	gnome-keyring? ( app-crypt/libsecret )
	nls? ( virtual/libintl )
	sasl? ( virtual/gsasl )
	ssl? ( net-libs/gnutls:0=[idn?] )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
	virtual/pkgconfig"

DOCS="AUTHORS ChangeLog NEWS NOTES README THANKS"

src_configure() {
	econf \
		$(use_enable nls) \
		$(use_with ssl tls gnutls) \
		$(use_with sasl libgsasl) \
		$(use_with idn libidn) \
		$(use_with gnome-keyring libsecret)
}

src_install() {
	default

	if use vim-syntax ; then
		insinto /usr/share/vim/vimfiles/syntax
		doins scripts/vim/mpop.vim
	fi
}