# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit java-pkg eutils versionator

DESCRIPTION="Open-source Java-based Web Services RPC technology, supporting XML-RPC, SOAP and REST"
HOMEPAGE="http://xins.sourceforge.net/"
MY_PV=$(replace_version_separator 3 '-')
SRC_URI="mirror://sourceforge/xins/${PN}-${MY_PV}.tgz"

LICENSE="BSD"
SLOT="1.4"
KEYWORDS="~x86"
IUSE="debug doc examples jikes source"
S="${WORKDIR}/${PN}-${MY_PV}"

RDEPEND=">=virtual/jdk-1.4
	>=dev-java/ant-core-1.6.2
	>=dev-java/commons-logging-1.0
	>=dev-java/commons-codec-1.3
	=dev-java/commons-httpclient-3*
	=dev-java/jakarta-oro-2.0*
	>=dev-java/log4j-1.2
	=dev-java/servletapi-2.3*
	>=dev-java/xmlenc-0.52"

DEPEND="${RDEPEND}
	sys-apps/sed
	jikes? ( dev-java/jikes )
	source? ( app-arch/zip )"

src_unpack() {
	unpack ${A}
	cd ${S}
	rm -rf build docs lib/*
	epatch ${FILESDIR}/${PN}-script.patch
}

src_compile() {
	local antflags="java"
	local classpath="$(java-pkg_getjars commons-logging,commons-codec,commons-httpclient-3,jakarta-oro-2.0,log4j,servletapi-2.3,xmlenc || die 'Unable to set classpath')"
	use debug && antflags="-Djavac.debug=true ${antflags}"
	use jikes && antflags="-Dbuild.compiler=jikes ${antflags}"
	use doc && antflags="${antflags} javadoc"
	CLASSPATH=${classpath} ant ${antflags} || die "Processing of Ant build file failed."
}

src_install() {
	local SD=/usr/share/${PN}-${SLOT}
	local LI=${SD}/installment
	dobin bin/xins
	dosed "s/%%PN-SLOT%%/${PN}-${SLOT}/g" /usr/bin/xins
	use source && java-pkg_dosrc src/java-*/*
	rm -rf src/java-*
	java-pkg_dojar build/*.jar
	dodir ${LI}
	cp -R .version.properties build.xml src ${D}/${LI}
	dosym ${SD}/lib ${LI}/build
	dodir ${LI}/lib
	if use doc; then
		mkdir -p htmldoc/api
		cp -R docs/javadoc/* htmldoc/api/
		java-pkg_dohtml -r htmldoc/*
	fi
	if use examples; then
		local ED=/usr/share/doc/${PF}/examples
		dodir ${ED}
		cp -R demo/* ${D}/${ED}/
	fi
}