mupen64-0.5.ebuild

mupen64-0.5.ebuild (text/plain), 2.53 KB, created by Bernhard Reiter on 2005-12-10 16:42:53 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-emulation/mupen64/mupen64-0.4-r2.ebuild,v 1.5 2005/06/02 23:02:27 mr_bones_ Exp $

inherit eutils games

DESCRIPTION="A Nintendo 64 (N64) emulator"
HOMEPAGE="http://mupen64.emulation64.com/"
SRC_URI="http://mupen64.emulation64.com/files/${PV}/mupen64_src-${PV}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="avi gtk2"

RDEPEND="sys-libs/zlib
	!gtk2? ( =x11-libs/gtk+-1.2* )
	gtk2? ( >=x11-libs/gtk+-2 )
	media-libs/libsdl"
DEPEND="${RDEPEND}
	gtk2? ( dev-util/pkgconfig )"

S=${WORKDIR}/mupen64_src-${PV}

src_unpack() {
	unpack ${A}
	epatch "${FILESDIR}/${PN}-gentoo.patch"

	cd "${S}"
	
	sed -i "s:#undef WITH_HOME:#define WITH_HOME \"/usr/games/\":" config.h \
		|| die "sed failed"
	if ! use gtk2; then
		sed -i "s:#define GTK2_SUPPORT 1:#undef GTK2_SUPPORT:" config.h \
			|| die "sed failed"
	fi
	if use avi; then
		sed -i "s:#undef VCR_SUPPORT:#define VCR_SUPPORT 1:" config.h \
			|| die "sed failed"
	fi

	sed -i \
		-e "s:CFLAGS.*=\(.*\):CFLAGS=-fPIC ${CFLAGS}:" \
		-e "s:CXXFLAGS.*=\(.*\):CXXFLAGS=-fPIC ${CXXFLAGS}:" \
		Makefile \
		|| die "sed failed"
}

src_compile() {
	emake mupen64 || die "emake failed on $d"
	if use avi; then
		rm -f ${S}/r4300/r4300.o ${S}/r4300/interupt.o \
			${S}/memory/memory.o ${S}/memory/pif.o
		sed -i "s:#define VCR_SUPPORT 1:#undef VCR_SUPPORT:" config.h \
			|| die "sed failed"
	fi
	emake mupen64_nogui || die "emake failed"
	emake plugins/mupen64_input.so || die "emake failed"
	emake plugins/mupen64_hle_rsp_azimer.so || die "emake failed"
	emake plugins/dummyaudio.so || die "emake failed"
	emake plugins/mupen64_audio.so || die "emake failed"
	emake plugins/mupen64_soft_gfx.so || die "emake failed"
}

src_install() {
	local dir=${GAMES_LIBDIR}/${PN}

	exeinto "${GAMES_BINDIR}"
	doexe mupen64 || die "doexe failed"
	doexe mupen64_nogui || die "doexe failed"
	
	insinto "${dir}"
	doins mupen64.ini || "doins failed"
	
	dodir ${dir}/save
	
	cp -r lang roms plugins "${D}/${dir}/" \
		|| die "cp failed"

	rm "${D}/${dir}/plugins/empty"
	dodoc *.txt
	cp doc/readme.pdf "${D}/usr/share/doc/${PF}"

	domenu ${FILESDIR}/mupen64.desktop
	doicon ${FILESDIR}/mupen64.png

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	echo
	ewarn "If you are upgrading from previous version of mupen64"
	ewarn "backup your saved games then do a rm -rf on your"
	ewarn ".mupen64 directory. After launching the new mupen copy"
	ewarn "your saved games to the original place."
	echo
}