# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit distutils eutils webapp

DESCRIPTION="Trac is a minimalistic web-based project management, wiki and bug/issue tracking system."
HOMEPAGE="http://trac.edgewall.com/"
SRC_URI="http://ftp.edgewall.com/pub/trac/${P}.tar.gz"

LICENSE="trac"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="vhosts cgi fastcgi postgres sqlite enscript silvercity darcs"

# doing so because utils (such as trac-admin), manpages... overlap
SLOT="0"
WEBAPP_MANUAL_SLOT="yes"

# we need virtual/httpd-cgi to bring apache/lighttpd/whatever in when USE cgi
# we need virtual/httpd-fcgi to bring mod_fastcgi/lighttpd/whtever in when USE fastcgi
# we need virtual/httpd-python to bring mod_python/whatever in (when USE python?)
DEPEND="$DEPEND
	>=dev-lang/python-2.3
	app-text/pytextile
	>=dev-python/docutils-0.3.3
	dev-libs/clearsilver
	>=dev-util/subversion-1.1
	sqlite? ( >=dev-python/pysqlite-2 )
	postgres? ( dev-python/psycopg )
	enscript? ( app-text/enscript )
	silvercity? ( app-text/silvercity )
	darcs? ( dev-util/darcs )"

pkg_setup () {
	if ! use postgres && ! use sqlite ; then
		eerror "You must select at least one database backend,"
		eerror "using sqlite or postgres USE flags."
		die "no database backend selected!"
	fi

	webapp_pkg_setup
}

src_unpack () {
	unpack ${A}
	if use darcs ; then
		cd ${S}
		epatch ${FILESDIR}/${PV}-generalization.patch
	fi
}

src_install () {
	# project databases might go in here
	keepdir /var/lib/trac

	webapp_src_preinst
	distutils_src_install

	dodoc AUTHORS INSTALL RELEASE THANKS UPGRADE
	rm ${D}/usr/share/doc/${PF}/COPYING.gz
	rm ${D}/usr/share/doc/${PF}/MANIFEST.in.gz
	rm ${D}/usr/share/doc/${PF}/PKG-INFO.gz

	# if needed, install cgi/fcgi scripts for webapp-config
	local my_dir=${D}/usr/share/trac
	if use cgi ; then
		mv ${my_dir}/cgi-bin/trac.cgi ${D}${MY_CGIBINDIR} || die
	fi
	if use fastcgi ; then
		mv ${my_dir}/cgi-bin/trac.fcgi ${D}${MY_CGIBINDIR} || die
	fi
	rm -rf ${my_dir}/cgi-bin || die

	for lang in en; do
		webapp_postinst_txt ${lang} ${FILESDIR}/${PV}-postinst-${lang}.txt
	done

	webapp_src_install
}