# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="Console display library used by most text viewer"
HOMEPAGE="http://www.s-lang.org/"
SRC_URI="ftp://space.mit.edu/pub/davis/slang/v${PV%.*}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cjk pcre png"

DEPEND=">=sys-libs/ncurses-5.2-r2
	pcre? ( dev-libs/libpcre )
	png? ( media-libs/libpng )"

MAKEOPTS="-j1"

src_unpack() {
	unpack ${A}
	cd "${S}"
	sed -i \
		-e '/^SLANG_INST_INC/s/-I@includedir@/-I@SRCDIR@ -I@includedir@/' \
		-e '/^SLANG_INST_LIB/s/-L@libdir@/-L@OBJDIR@ -L@ELFDIR@ -L@libdir@/' \
		slsh/Makefile.in || die
	if use cjk ; then
		sed -i -e '/SLANG_HAS_KANJI_SUPPORT/s/0/1/' src/sl-feat.h || die
	fi
}

src_compile() {
	econf \
		$(use_with pcre) \
		$(use_with png) || die "econf failed"
	emake all || die "make all failed"
	emake elf || die "make elf failed"
	cd slsh
	emake slsh || die "make slsh failed"
}

src_install() {
	make DESTDIR="${D}" install install-elf || die "make install failed"
	rm -rf ${D}/usr/share/doc/slang
	dodoc NEWS README *.txt
	dodoc doc/*.txt doc/internal/*.txt doc/text/*.txt 
	dohtml doc/slangdoc.html
}