new ebuild

mamory-0.2.20-r1.ebuild (text/plain), 1013 bytes, created by Christian Birchinger (RETIRED) on 2005-11-17 04:00:34 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games autotools

DESCRIPTION="rom management tools and library"
HOMEPAGE="http://mamory.sourceforge.net/"
SRC_URI="mirror://sourceforge/mamory/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="ppc x86 amd64"
IUSE=""

DEPEND="sys-devel/autoconf
	sys-devel/automake
	sys-devel/libtool"

RDEPEND=""

src_unpack() {
	unpack ${A}
	
	cd ${S}

	# Remove hardcoded CFLAGS options
	sed -i configure.in \
		-e '/AC_ARG_ENABLE(debug,/ {N;N;N;d}'

	# Make it possible for eautoreconf to fix fPIC etc.
	sed -i common/Makefile.am \
		-e '/libcommon_la_LDFLAGS= -static/d'

	AT_M4DIR="config" eautoreconf || die
}	

src_compile() {
	egamesconf \
		--disable-dependency-tracking \
		--includedir=/usr/include || die
	emake || die "emake failed"
}

src_install() {
	make DESTDIR="${D}" install || die "make install failed"
	dodoc AUTHORS ChangeLog README TODO
	dohtml DOCS/mamory.html
	prepgamesdirs
}