# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils java-pkg

DESCRIPTION="Library for interactive visualization and analysis of numerical data"
HOMEPAGE="http://www.ssec.wisc.edu/~billh/visad.html"
SRC_URI="ftp://ftp.ssec.wisc.edu/pub/visad-2.0/visad_src-${PV}.jar"

LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64 ~ppc"
IUSE="doc source jikes"

DEPEND=">=virtual/jdk-1.4
	>=dev-java/ant-core-1.5.4
	>=dev-java/blackdown-java3d-bin-1.3
	jikes? ( dev-java/jikes )
	source? ( app-arch/zip )"
RDEPEND=">=virtual/jre-1.4"

src_unpack() {
	mkdir -p ${P}/src || die "dir creation failed"
	cd ${P}/src
	jar -xf ${DISTDIR}/visad_src-${PV}.jar || die "cannot unpack the source"
	cd ..
	cp ${FILESDIR}/build.xml .
	mkdir lib || die "dir creation failed"
	cd lib
	java-pkg_jar-from blackdown-java3d-bin
	cd ..
	epatch ${FILESDIR}/vm_memsize.patch
}

src_compile() {
	# Populate classpath
	local classpath="$(java-pkg_getjars blackdown-java3d-bin)"
	local antflags="jar -Dproject.name=${PN} -Dclasspath=${classpath}"
	use jikes && antflags="-Dbuild.compiler=jikes ${antflags}"
	use doc && antflags="${antflags} -Dpackage.name=visad.* javadoc"

	ant ${antflags} || die "Compilation failed"
}

src_install() {
	java-pkg_dojar dist/*.jar || die "jar installation failed"

	if use source ; then
		java-pkg_dosrc src/* || die "cannot install sources"
	fi

	if use doc ; then
		java-pkg_dohtml -r dist/doc/*
	fi
}