drawboard-1.52.ebuild

drawboard-1.52.ebuild (text/plain), 1.71 KB, created by James Le Cuirot on 2005-11-09 08:16:00 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header:

inherit eutils

MY_PV=$(echo ${PV} | sed "s/\./_/g")

DESCRIPTION="Java applet used to make graphical teleconferences"
HOMEPAGE="http://drawboard.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}_${MY_PV}.zip"
KEYWORDS="~x86"
SLOT="0"
LICENSE="GPL-2"
IUSE=""

DEPEND="virtual/jdk"
	
RDEPEND="virtual/jre"

src_unpack() {
	mkdir ${S}
	cd ${S}
	unpack ${A}
	
	rm -f drawboard.jar

	# All the unicode cases have been commented out... except this one...
	sed -i "s:case '\\\\u00AC'\: return Z__;://\0:" source/Alphabet.java
	
	# Change test.html to index.html so you don't have the specify the page.
	mv test.html index.html

	epatch ${FILESDIR}/changed.patch
}

src_compile() {
	$(java-config -c) -encoding ISO-8859-1 -d . source/*.java || die "Build failed!"
	$(java-config -j) cf drawboard.jar drawboard about.gif
}

src_install() {
	dodoc BUGS CHANGELOG HISTORY INSTALL README TODO
	dohtml -r doc/*
	
	insinto /usr/share/${PN}
	doins -r *.gif *.png *.html skin drawboard.jar
	
	exeinto /etc/init.d
	newexe ${FILESDIR}/drawboard-init drawboard
	
	insinto /etc/conf.d
	newins ${FILESDIR}/drawboard-conf drawboard
}

pkg_postinst() {
	einfo ""
	einfo "The Drawboard client must be held on a web server. The easiest way to do"
	einfo "this is to symlink from your web root to the /usr/share/drawboard directory."
	einfo "For example..."
	einfo ""
	einfo "  ln -s /usr/share/drawboard /var/www/localhost/htdocs"
	einfo ""
	einfo "You can then access the Drawboard client by pointing your browser to"
	einfo "http://<hostname>/drawboard. Start the Drawboard server with..."
	einfo ""
	einfo "  /etc/init.d/drawboard start"
	einfo ""
}