# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_PV=0.7
DESCRIPTION="Base files for Enlightenment epplets and some epplets"
HOMEPAGE="http://www.enlightenment.org/"
SRC_URI="mirror://sourceforge/enlightenment/epplets-${MY_PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

# This ebuild is only for enlightenment 16.8 and higher
# directory structure is different!
DEPEND="virtual/x11
	virtual/glut
	>=media-libs/imlib-1.9.10
	>=x11-wm/enlightenment-0.16.8
	media-sound/esound"

S=${WORKDIR}/${PN}-${MY_PV}

src_unpack() {
	unpack ${A}
	cd ${S}
	epatch ${FILESDIR}/${MY_PV}-compmgr-fix.patch #68057
	# epplet api and some files need fixing for correct
	# home directory location. ~/.e16 instead of ~/.enlightenment
	# for some reason it was hard coded :(
	epatch ${FILESDIR}/e16.8.fix.patch
}

src_compile() {
	# EROOT is different here and must be under e16
	export EROOT=/usr/share/e16
	export EBIN=/usr/bin
	econf || die
	emake || die
}

src_install() {
	make DESTDIR="${D}" install || die
	dodoc ChangeLog
}