# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils qt3

MY_PN="${PN/-/_}"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="A Linux GUI for the iRiver iFP flash portable player based on QT"
HOMEPAGE="http://ifpgui.sourceforge.net"
SRC_URI="mirror://sourceforge/ifpgui/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="doc"

RDEPEND="dev-libs/libifp
	$(qt_min_version 3.3)
	>=dev-libs/libusb-0.1.7"
DEPEND="${RDEPEND}
	>=sys-apps/sed-4
	doc? (>=app-doc/doxygen-1.3.7)"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	unpack ${A}

	cd ${S}

	# for common problems no_fixpath with non-standard
	# PORTAGE_TMPDIR
	epatch ${FILESDIR}/${PN}-config_no_fixpath.patch

	# some Doxyfile improvements
	epatch ${FILESDIR}/${PN}-doxyfile_fixes.patch
	sed -i -e '/PROJECT_NUMBER/ s/0.9.3/'${PV}'/' \
		-e '/PROJECT_NAME/ s/'${MY_PN}'.*$/'${PN}'/' \
		-e '/OUTPUT/ s/\/home.*$/\.\/doc/' Doxyfile
	use doc && mkdir doc

	# we want to use system libifp
	rm -rf src/libifp src/ifp.h
	epatch ${FILESDIR}/${PN}-use_system_libifp.patch
}

src_compile() {
	cd ${S}/src
	${QTDIR}/bin/qmake src.pro \
		QMAKE_CXXFLAGS_RELEASE="${CXXFLAGS}" \
		QMAKE_RPATH= \
		|| die "qmake src.pro failed"

	cd ${S}
	${QTDIR}/bin/qmake ifp_gui.pro \
		QMAKE_CXXFLAGS_RELEASE="${CXXFLAGS}" \
		QMAKE_RPATH= \
		|| die "qmake ifp_gui.pro failed"

	addwrite "${QTDIR}/etc/settings"

	emake || die "emake failed"
	
	use doc && doxygen
}

src_install() {
	dobin src/${PN}
	dodoc README CHANGELOG

	insinto /usr/share/${PF}
	doins nonroot.sh

	if use doc; then
		dodir /usr/share/doc/${PF}
		cp -ar doc/* ${D}/usr/share/doc/${PF}
	fi;

	domenu ${FILESDIR}/${PN}.desktop
	doicon ${FILESDIR}/${PN}.png
}

pkg_postinst() {
	echo
	ewarn "If you want to use ifp_gui without root-privileges, you should run "
	ewarn "ebuild /var/db/pkg/${CATEGORY}/${PF}/${PF}.ebuild config"
	ewarn "or"
	ewarn "/usr/share/${PF}/nonroot.sh"
	ewarn "to add approprate rules to your hotplug scripts"
	echo
}

pkg_config() {
	${ROOT}/usr/share/${PF}/nonroot.sh || die "config failed"
}