mail-client/sylpheed-claws-acpi-notifier/sylpheed-claws-acpi-notifier-0.3.ebuild

sylpheed-claws-acpi-notifier-0.3.ebuild (text/plain), 1.33 KB, created by TGL on 2005-11-04 08:16:20 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_PN="${PN#sylpheed-claws-}"
MY_PN="${MY_PN/-/_}"
MY_P="${MY_PN}-${PV}"
SC_BASE="1.9.99"

DESCRIPTION="This plugin enables mail notification via LEDs on some laptops."
HOMEPAGE="http://claws.sylpheed.org"
SRC_URI="mirror://sourceforge/sylpheed-claws/sylpheed-claws-external-plugins-${SC_BASE}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""
DEPEND=">=mail-client/sylpheed-claws-${SC_BASE}
    >=x11-libs/gtk+-2.4"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${MY_P}-ibm.patch"
}

src_install() {
	make DESTDIR="${D}" install
	rm -f ${D}usr/lib*/sylpheed-claws/plugins/*.{a,la}
	dodoc AUTHORS ChangeLog NEWS README
}

pkg_postinst() {
	local procfile
	for procfile in \
		/proc/driver/acerhk/led \
		/proc/acpi/asus/mled \
		/proc/acpi/ibm/led
	do
		if [[ -f ${procfile} ]] ;then
			einfo "Make sure ${procfile} is writable by users of this plugin."
		fi
	done
	if [[ ! -f /proc/driver/acerhk/led ]] \
	&& [[ ! -f /proc/acpi/asus/mled ]] \
	&& [[ ! -f /proc/acpi/ibm/led ]] ; then
		einfo "To use this plugin, you will have to find the /proc interface"
		einfo "that controls your LED. Whatever it is, make sure it's writable"
		einfo "by users who will run this plugin."
	fi
}