# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-drivers/xf86-video-sunffb/xf86-video-sunffb-1.0.0.1.ebuild,v 1.1 2005/10/20 06:04:53 joshuabaergen Exp $

# Must be before x-modular eclass is inherited
#SNAPSHOT="yes"

inherit x-modular autotools

DESCRIPTION="X.Org driver for sunffb cards"
KEYWORDS="~sparc ~x86"
IUSE="dri"
RDEPEND="x11-base/xorg-server"
DEPEND="${RDEPEND}
	x11-proto/xproto
	dri? ( x11-proto/xf86driproto )"

CONFIGURE_OPTIONS="$(use_enable dri)"

pkg_setup() {
	if use dri && ! built_with_use x11-base/xorg-server dri; then
		die "Build x11-base/xorg-server with USE=dri."
	fi
}

src_unpack() {
	unpack ${A}
	cd ${S}
	einfo 'Add assembler routines to required modules'
	sed -i -e 's:ffb_zeroarc.c:ffb_zeroarc.c ffb_asm.s VISmoveImage.s:' \
		src/Makefile.am
	einfo 'Set up to assemble properly'
	sed -i -e \
		's:LIBTOOL:LIBTOOL	\
		CCASFLAGS="-x assembler-with-cpp -Wa,-Av9a"	\
		AM_PROG_AS:' \
		configure.ac
	echo 'CCASFLAGS="-x assembler-with-cpp -Wa,-Av9a"' >> configure.ac
	echo 'AM_PROG_AS' >> configure.ac
	eautoreconf
}