# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-fps/americas-army/americas-army-230.ebuild,v 1.9 2005/10/23 21:14:53 wolf31o2 Exp $

inherit eutils games

MY_P="armyops${PV}-linux.run"
DESCRIPTION="America's Army: Special Forces - military simulations by the U.S. Army to provide civilians with insights on soldiering"
HOMEPAGE="http://www.americasarmy.com/"
SRC_URI="mirror://3dgamers/${PN/-/}/${MY_P}
	dedicated? (
		http://dev.gentoo.org/~wolf31o2/sources/dump/${PN}-all-0.1.tar.bz2
		mirror://gentoo/${PN}-all-0.1.tar.bz2 )"

LICENSE="Army-EULA"
SLOT="0"
KEYWORDS="~x86 ~amd64"
RESTRICT="nostrip nomirror"

IUSE="opengl dedicated"

DEPEND="virtual/libc
	app-arch/unzip"
RDEPEND="virtual/libc
	opengl? ( virtual/opengl )
	amd64? ( app-emulation/emul-linux-x86-xlibs
		app-emulation/emul-linux-x86-compat
		|| ( >=media-video/nvidia-glx-1.0.6629-r3
			>=media-video/ati-drivers-8.8.25-r1 ) )
	dedicated? ( app-misc/screen )"

S=${WORKDIR}
dir=${GAMES_PREFIX_OPT}/${PN}
Ddir=${D}/${dir}

pkg_setup() {
	games_pkg_setup
	ewarn "The installed game takes about 1.6GB of space when installed and 2.4GB of space in ${PORTAGE_TMPDIR} to build!"
}

src_unpack() {
	unpack_makeself ${DISTDIR}/${MY_P} || die "unpacking game"
	tar -zxf setupstuff.tar.gz || die
	if use dedicated; then
		unpack ${PN}-all-0.1.tar.bz2 || die
	fi
}

src_install() {
	einfo "This will take a while ... go get a pizza or something"

	dodir ${dir}

	tar -jxf armyops${PV}.tar.bz2 -C ${Ddir}/ || die "armyops untar failed"
	tar -jxf binaries.tar.bz2 -C ${Ddir}/ || die "binaries untar failed"

	dodoc README.linux
	insinto ${dir}
	doins ArmyOps.xpm README.linux ArmyOps${PV}_EULA.txt || die "doins failed"
	newicon ArmyOps.xpm armyops.xpm || die "doins failed"
	exeinto ${dir}
	doexe bin/armyops || die "doexe failed"

	if use dedicated; then
		newinitd ${S}/armyops-ded.rc armyops-ded
		newconfd ${S}/armyops-ded.conf. armyops-ded
		games_make_wrapper armyops-ded ./server-bin ${dir}/System
	fi

	games_make_wrapper armyops ./armyops "${dir}" "${dir}"

	prepgamesdirs
	make_desktop_entry armyops "America's Army" armyops.xpm
}

pkg_postinst() {
	games_pkg_postinst
	if use dedicated; then
		einfo "To start a dedicated server, run"
		einfo "	/etc/init.d/armyops-ded start"
		echo
	fi
	if use opengl; then
		einfo "To play the game run:"
		einfo " armyops"
		echo
	fi
}