# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( python3_{7..9} )
inherit cmake llvm llvm.org python-any-r1

DESCRIPTION="Polyhedral optimizations for LLVM"
HOMEPAGE="https://polly.llvm.org/"

LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
SLOT="$(ver_cut 1)"
KEYWORDS="~amd64"
IUSE="doc test"
RESTRICT="!test? ( test )"

RDEPEND="~sys-devel/llvm-${PV}:${SLOT}="
DEPEND="${RDEPEND}"
BDEPEND="
	>=dev-util/cmake-3.16
	$(python_gen_any_dep "
		doc? ( dev-python/sphinx[\${PYTHON_USEDEP}] )
		test? ( >=dev-python/lit-9.0.1[\${PYTHON_USEDEP}] )
	")"

LLVM_COMPONENTS=( polly )
LLVM_MANPAGES=build
llvm.org_set_globals

python_check_deps() {
	use doc && has_version "dev-python/sphinx[${PYTHON_USEDEP}]" || \
		use test && has_version "dev-python/lit[${PYTHON_USEDEP}]"
}

pkg_setup() {
	LLVM_MAX_SLOT=${SLOT} llvm_pkg_setup
	( use doc || use test ) && python-any-r1_pkg_setup
}

src_configure() {
	local llvm_prefix="${EPREFIX}/usr/lib/llvm/${SLOT}"
	local mycmakeargs=(
		-DBUILD_SHARED_LIBS=ON
		-DLLVM_LINK_LLVM_DYLIB=ON
		-DLLVM_POLLY_LINK_INTO_TOOLS=OFF
		-DCMAKE_INSTALL_PREFIX="${llvm_prefix}"
		-DCMAKE_PREFIX_PATH="${llvm_prefix}/$(get_libdir)/cmake/llvm"
	)
	use doc && mycmakeargs+=(
		-DLLVM_BUILD_DOCS=ON
		-DLLVM_ENABLE_SPHINX=ON
		-DSPHINX_WARNINGS_AS_ERRORS=OFF
		-DCMAKE_INSTALL_MANDIR="${llvm_prefix}/share/man"
		-DPOLLY_INSTALL_SPHINX_HTML_DIR="${EPREFIX}/usr/share/doc/${PF}/html"
		-DPython3_EXECUTABLE="${PYTHON}"
	)
	use test && mycmakeargs+=(
		-DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
		-DLLVM_LIT_ARGS="$(get_lit_flags)"
		-DPython3_EXECUTABLE="${PYTHON}"
	)

	cmake_src_configure
}

src_test() {
	# respect TMPDIR!
	local -x LIT_PRESERVES_TMP=1
	cmake_build check-polly
}