- 

# Copyright 1999-2021 Gentoo Authors

# Distributed under the terms of the GNU General Public License v2

EAPI=7

MY_P="tomcat-connectors-${PV#-*}-src"

inherit apache-module readme.gentoo-r1

DESCRIPTION="JK module for connecting Tomcat and Apache using the ajp13 protocol"

HOMEPAGE="https://tomcat.apache.org/connectors-doc/"

SRC_URI="mirror://apache/tomcat/tomcat-connectors/jk/${MY_P}.tar.gz"

S="${WORKDIR}/${MY_P}/native"

LICENSE="Apache-2.0"

SLOT="0"

KEYWORDS="~amd64 ~ppc ~x86"

IUSE=""

APACHE2_MOD_FILE="${S}/apache-2.0/${PN}.so"

APACHE2_MOD_CONF="88_${PN}"

APACHE2_MOD_DEFINE="JK"

CONF_DIR="${WORKDIR}/${MY_P}/conf"

need_apache2

DOC_CONTENTS="

	Advanced Directives and Options can be found at:

	https://tomcat.apache.org/connectors-doc/reference/workers.html

"

src_configure() {

	econf \

		--with-apxs=${APXS}

}

src_compile() {

	emake LIBTOOL="/bin/sh $(pwd)/libtool --silent"

}

src_install() {

	# otherwise installs to /mod_jk.so

	APACHE_MODULESDIR="/usr/$(get_libdir)/apache2/modules"

	# install the workers.properties file

	insinto "${APACHE_CONFDIR}"

	newins "${CONF_DIR}/workers.properties" \

		jk-workers.properties

	doins "${CONF_DIR}/uriworkermap.properties"

	apache-module_src_install

	readme.gentoo_create_doc

}

pkg_postinst() {

	readme.gentoo_print_elog

}