machineball-1.0.ebuild

machineball-1.0.ebuild (text/plain), 925 bytes, created by Adrian Frühwirth on 2005-09-21 17:44:32 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games toolchain-funcs

MY_PN="${PN}-src"
MY_PV="${PV}-1"
MY_P=${MY_PN}-${MY_PV}

DESCRIPTION="A futuristic ball game with simple rules"
HOMEPAGE="http://benny.kramekweb.com/machineball/"
SRC_URI="http://benny.kramekweb.com/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

DEPEND=">=media-libs/allegro-4.0.2
	>=media-libs/allegrogl-0.1.12
	>=media-libs/dumb-0.9.1
	>=media-libs/aldumb-0.9.1
	>=dev-games/ode-0.035"

S="${WORKDIR}/${MY_PN}"

src_unpack() {
	unpack ${A}
	cd "${S}"

	sed -i \
		-e "s#gcc#$(tc-getCC) ${CFLAGS}#" \
		Makefile \
		|| die "sed failed"
}

src_compile() {
	emake CXX=$(tc-getCXX) || die "emake failed"
}

src_install() {
	dogamesbin machineball || die "dogamesbin failed"
	insinto /usr/share/pixmaps
	doins *.xpm
	dodoc README

	prepgamesdirs
}