ebuild for 0.21

widelands-0.21-r101.ebuild (text/plain), 1.88 KB, created by Florian E. Teply on 2021-02-01 16:35:41 UTC

# Copyright 2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( python3_{6,7,8} )
LUA_COMPAT=( lua5-1 )

inherit desktop cmake lua-single python-any-r1 xdg

MY_PV="build$(ver_cut 2-)"
MY_P="${PN}-${MY_PV/_/-}"

DESCRIPTION="A game similar to Settlers 2"
HOMEPAGE="https://www.widelands.org/"
SRC_URI="https://launchpad.net/widelands/build$(ver_cut 2)/${MY_PV/_/-}/+download/${MY_P}-source.tar.gz"

LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="
	>=dev-libs/boost-1.48:=
	dev-libs/icu:=
	media-libs/glew:0=
	media-libs/libglvnd
	media-libs/libpng:0=
	media-libs/libsdl2[video]
	media-libs/sdl2-image[jpeg,png]
	media-libs/sdl2-mixer[vorbis]
	media-libs/sdl2-ttf
	sys-libs/zlib:=[minizip]"
DEPEND="${RDEPEND}
	${PYTHON_DEPS}
"
BDEPEND="
	sys-devel/gettext
"

CMAKE_BUILD_TYPE="Release"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	cmake_src_prepare

	sed -i -e 's:__ppc__:__PPC__:' src/map_io/s2map.cc || die
	sed -i -e '/GTK_UPDATE_ICON_CACHE/,$d' xdg/CMakeLists.txt || die
}

src_configure() {
	local mycmakeargs=(
		-DOPTION_BUILD_WEBSITE_TOOLS=OFF

		# Upstream's cmake files are totally fscked up...
		-DCMAKE_INSTALL_PREFIX="${EPREFIX}"/usr/${PF}
		# Game is NOT happy being moved from /usr/share/games
		-DWL_INSTALL_DATADIR="${EPREFIX}"/usr/share/games/${PN}
	)
	cmake_src_configure
}

src_install() {
	cmake_src_install

	# move game binary to correct location
	dodir /usr/bin
	mv "${ED}"/usr/${PF}/${PN} "${ED}"/usr/bin || die
	mv "${ED}"/usr/${PF}/COPYING "${ED}"/usr/share/doc/${PF}/ || die
	mv "${ED}"/usr/${PF}/VERSION "${ED}"/usr/share/doc/${PF}/ || die
	rm "${ED}"/usr/${PF}/ChangeLog || die
	rm "${ED}"/usr/${PF}/CREDITS || die
	rmdir "${ED}"/usr/${PF} || die

	newicon data/images/logos/wl-ico-128.png ${PN}.png
	make_desktop_entry ${PN} ${PN^}
}

pkg_postinst() {
	xdg_icon_cache_update
}

pkg_postrm() {
	xdg_icon_cache_update
}