From 34265125681eccc0de22ffc07940513525ffdef8 Mon Sep 17 00:00:00 2001
From: Salah Coronya <salah.coronya@gmail.com>
Date: Tue, 29 Dec 2020 20:32:42 -0600
Subject: [PATCH 2/4] app-crypt/tpm2-tss: Add libressl support

Closes: https://bugs.gentoo.org/762445
Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Salah Coronya <salah.coronya@gmail.com>
---
 app-crypt/tpm2-tss/tpm2-tss-3.0.3-r1.ebuild | 80 +++++++++++++++++++++
 1 file changed, 80 insertions(+)
 create mode 100644 app-crypt/tpm2-tss/tpm2-tss-3.0.3-r1.ebuild

diff --git a/app-crypt/tpm2-tss/tpm2-tss-3.0.3-r1.ebuild b/app-crypt/tpm2-tss/tpm2-tss-3.0.3-r1.ebuild
new file mode 100644
index 00000000000..6a4f5b39d0e
--- /dev/null
+++ b/app-crypt/tpm2-tss/tpm2-tss-3.0.3-r1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools linux-info tmpfiles udev
+
+DESCRIPTION="TCG Trusted Platform Module 2.0 Software Stack"
+HOMEPAGE="https://github.com/tpm2-software/tpm2-tss"
+SRC_URI="https://github.com/tpm2-software/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="doc +fapi libressl mbedtls static-libs test"
+
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="	?? ( libressl mbedtls  )
+		fapi? ( !mbedtls )"
+
+RDEPEND="acct-group/tss
+	acct-user/tss
+	fapi? ( dev-libs/json-c
+		net-misc/curl )
+	libressl? ( dev-libs/libressl:= )
+	mbedtls? ( net-libs/mbedtls:= )
+	!libressl? (
+		!mbedtls? ( dev-libs/openssl:= )
+	)"
+DEPEND="${RDEPEND}
+	test? ( dev-util/cmocka )"
+BDEPEND="virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.0.0-Dont-run-systemd-sysusers-in-Makefile.patch"
+	"${FILESDIR}/${PN}-3.0.1-Fix-underquoting-in-configure-ac.patch"
+	"${FILESDIR}/${PN}-2.4.5-fix-compile-with-libressl.patch"
+)
+
+pkg_setup() {
+	local CONFIG_CHECK=" \
+		~TCG_TPM
+	"
+	linux-info_pkg_setup
+	kernel_is ge 4 12 0 || ewarn "At least kernel 4.12.0 is required"
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--localstatedir=/var \
+		$(use_enable doc doxygen-doc) \
+		$(use_enable fapi) \
+		$(use_enable static-libs static) \
+		$(use_enable test unit) \
+		--disable-tcti-mssim \
+		--disable-defaultflags \
+		--disable-weakcrypto \
+		--with-crypto="$(usex mbedtls mbed ossl)" \
+		--with-runstatedir=/run \
+		--with-udevrulesdir="$(get_udevdir)/rules.d" \
+		--with-udevrulesprefix=60- \
+		--with-sysusersdir="/usr/lib/sysusers.d" \
+		--with-tmpfilesdir="/usr/lib/tmpfiles.d"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	tmpfiles_process tpm2-tss-fapi.conf
+}
-- 
2.26.2