rizin-9999.ebuild

rizin-9999.ebuild (text/plain), 1.58 KB, created by Petross404(Petros S) on 2020-12-20 10:35:33 UTC

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit meson

DESCRIPTION="unix-like reverse engineering framework and commandline tools - fork of Radare2"
HOMEPAGE="https://rizin.re/ https://github.com/rizinorg/rizin"

if [[ ${PV} == *9999 ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/rizinorg/rizin.git"
else
	SRC_URI="https://github.com/rizinorg/rizin/archive/${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
fi

LICENSE="LGPL-3"
SLOT="0"
IUSE="debugger doc libuv pch +system-capstone +system-lz4 +system-zip +system-zlib +system-magic +system-openssl +system-tree-sitter +system-xxhash"
DOCS=( "README.md" )

RDEPEND="
	libuv? ( dev-libs/libuv )
	system-capstone? ( dev-libs/capstone:0= )
	system-lz4? ( app-arch/lz4 )
	system-zip? ( dev-libs/libzip )
	system-zlib? ( sys-libs/zlib )
	system-openssl? ( dev-libs/openssl )
	system-tree-sitter? ( dev-libs/tree-sitter )
"
DEPEND="${RDEPEND}"

src_prepare(){
	if [[ ${PV} == *9999 ]]; then
		PATCHES+=( "${FILESDIR}/${PN}-9999-drop-git-postfix.diff" )
	fi

	default
}

src_configure() {
	local emesonargs=(
		$(meson_use debugger debugger)
		$(meson_use libuv use_libuv)
		$(meson_use pch b_pch)

		$(meson_use system-capstone use_sys_capstone)
		$(meson_use system-magic use_sys_magic)
		$(meson_use system-zip use_sys_zip)
		$(meson_use system-zlib use_sys_zlib)
		$(meson_use system-lz4 use_sys_lz4)
		$(meson_use system-xxhash use_sys_xxhash)
		$(meson_use system-openssl use_sys_openssl)
		$(meson_use system-tree-sitter use_sys_tree_sitter)
	)
	meson_src_configure
}