tap-plugins-1.0.1.ebuild (multilib-compatible)

tap-plugins-1.0.1.ebuild (text/plain), 1.19 KB, created by Sophie Hamilton on 2020-12-11 19:16:41 UTC

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7
inherit eutils toolchain-funcs multilib multilib-minimal

if [[ "${PV}" == "9999" ]]; then
	inherit git-r3
	KEYWORDS="amd64 x86"
	EGIT_REPO_URI="git://github.com/tomszilagyi/${PN}.git"
	EGIT_PROJECT="${PN}.git"
else
	KEYWORDS="amd64 ~arm ~arm64 ~ppc x86"
	SRC_URI="https://github.com/tomszilagyi/tap-plugins/archive/v${PV}.tar.gz -> $P.tar.gz"
fi

DESCRIPTION="Tom's audio processing (TAP) LADSPA plugins"
HOMEPAGE="https://github.com/tomszilagyi/tap-plugins http://tap-plugins.sourceforge.net/"
LICENSE="GPL-2"
SLOT="0"
IUSE=""
DEPEND="media-libs/ladspa-sdk"
RDEPEND="${DEPEND}
	abi_x86_32? ( !<=app-emulation/emul-linux-x86-soundlibs-20130224-r2
					!app-emulation/emul-linux-x86-soundlibs[-abi_x86_32(-)] )"
DOCS=( README CREDITS )
PATCHES=( "${FILESDIR}/${PN}-1.0.1-makefile.patch" )

src_prepare() {
	default
	multilib_copy_sources
}

multilib_src_compile() {
	emake CC="$(tc-getCC)" OPT_CFLAGS="${CFLAGS}" EXTRA_LDFLAGS="${LDFLAGS}"
}

multilib_src_install() {
	exeinto /usr/$(get_libdir)/ladspa
	doexe *.so
}

multilib_src_install_all() {
	insinto /usr/share/ladspa/rdf
	doins *.rdf
	einstalldocs
}