tentative ebuild (new version)

teams-1.3.00.30857.ebuild (text/plain), 1.74 KB, created by Michelangelo Scopelliti on 2020-12-06 14:10:55 UTC

# Copyright 2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit desktop pax-utils unpacker xdg-utils

DESCRIPTION="Microsoft Teams, an Office 365 multimedia collaboration client, pre-release"
HOMEPAGE="https://products.office.com/en-us/microsoft-teams/group-chat-software/"
SRC_URI="https://packages.microsoft.com/repos/ms-teams/pool/main/t/${PN}/${PN}_${PV}_amd64.deb"

LICENSE="APSL-2 Apache-2.0 Artistic-2 BSD BSD-1 BSD-2 Boost-1.0 CC-BY-SA-3.0 CC0-1.0 ISC LGPL-2.1 MIT MIT-with-advertising ZLIB icu ms-teams-pre openssl"
SLOT="0"
KEYWORDS="-* ~amd64"
RESTRICT="bindist mirror splitdebug test"
IUSE="system-ffmpeg"

QA_PREBUILT="*"

RDEPEND="
	app-arch/bzip2
	app-crypt/libsecret
	dev-libs/libgcrypt
	dev-libs/nss
	media-gfx/graphite2
	media-libs/alsa-lib
	net-dns/libidn2
	net-libs/gnutls
	net-print/cups
	x11-libs/gtk+:3[X]
	x11-libs/libXScrnSaver
	x11-libs/libxkbfile
	system-ffmpeg? ( <media-video/ffmpeg-4.3[chromium] )"

S="${WORKDIR}"

src_prepare() {
	default
	sed -e "s@^TEAMS_PATH=.*@TEAMS_PATH=${EPREFIX}/opt/teams/teams@" \
		-i usr/bin/teams || die
	sed -e "s!^Categories=.*!Categories=Network;InstantMessaging;Telephony;!" \
		-e '/OnlyShowIn=/d' \
		-i usr/share/applications/teams.desktop || die
}

src_install() {
	insinto /opt
	doins -r usr/share/teams
	fperms +x /opt/teams/teams
	dobin usr/bin/teams
	domenu usr/share/applications/teams.desktop

	if use system-ffmpeg ; then
		rm -f "${D}"/opt/teams/libffmpeg.so || die

		sed -i "s:nohup:LDPATH=${EROOT}/usr/$(get_libdir)/chromium nohup"
		elog "Using system ffmpeg. This is experimental and may lead to crashes."
	fi
	doicon usr/share/pixmaps/teams.png
}

pkg_postinst() {
	xdg_desktop_database_update
}

pkg_postrm() {
	xdg_desktop_database_update
}