bfilter-0.9.4.ebuild

bfilter-0.9.4.ebuild (text/plain), 1.11 KB, created by Alan Swanson on 2005-08-27 12:16:13 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="An ad-filtering web proxy featuring an effective heuristic ad-detection algorithm"
HOMEPAGE="http://bfilter.sourceforge.net/"
SRC_URI="mirror://sourceforge/bfilter/${P}.tar.gz"
LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~x86"
IUSE="gui debug"

RDEPEND="sys-libs/zlib
	dev-libs/popt
	=dev-libs/libsigc++-1.2*
	gui? =dev-cpp/gtkmm-2.2*"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

pkg_preinst() {
	enewgroup bfilter
	enewuser bfilter -1 -1 -1 bfilter
}

src_unpack() {
	unpack ${A}
	cd ${S}

	# Provide user, group and chroot privilege lowering
	epatch ${FILESDIR}/${P}-droppriv.patch
}

src_compile() {
	econf `use_enable debug` `use_with gui` || die 

	emake || die
}

src_install() {
	make DESTDIR=${D} install || die

	# This is also created by openssh for privilege seperation
	dodir /var/empty
	keepdir /var/empty

	doman ${FILESDIR}/bfilter.8

	dodoc AUTHORS ChangeLog
	dohtml doc/*.png doc/*.html

	newinitd ${FILESDIR}/bfilter-init.d bfilter
	newconfd ${FILESDIR}/bfilter-conf.d bfilter
}