pdmenu-9999.ebuild using git-r3.eclass

pdmenu-9999.ebuild (text/plain), 1.42 KB, created by Duncan on 2020-11-01 02:25:49 UTC

# Copyright 1999-2020 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# JED 2020.1031 based on the 1.3.4-r1 ebuild

EAPI=6

inherit toolchain-funcs git-r3

DESCRIPTION="A simple console menu program"
HOMEPAGE="http://joeyh.name/code/pdmenu/"
LICENSE="GPL-2"
SLOT="0"
IUSE="nls gpm examples"
#SRC_URI="mirror://debian/pool/main/p/${PN}/pdmenu_${PV}.tar.gz"
EGIT_REPO_URI=git://git.joeyh.name/pdmenu
#S="${WORKDIR}/${PN}"

if [[ ${PV} == 9999 ]]; then
	KEYWORDS=
else
	EGIT_COMMIT=${PV}
	KEYWORDS="~amd64 ~mips ~x86"
fi


DEPEND="
	sys-libs/slang
	gpm? ( sys-libs/gpm )
	nls? ( sys-devel/gettext )"


RESTRICT="test"

PATCHES=(
	"${FILESDIR}"/${PN}-impl-dec.patch
)

DOCS=( doc/ANNOUNCE doc/BUGS doc/TODO )

src_prepare() {
	default
	sed \
		-e 's:\(-o pdmenu\):$(LDFLAGS) \1:g' \
		-i Makefile || die
}

src_configure() {
	CC=$(tc-getCC) econf \
		$(use_with gpm) \
		$(use_enable nls)
}

src_compile() {
	emake CC=$(tc-getCC)
}

src_install() {
	dobin "${PN}"
	use examples && dodoc -r examples
	mv "doc/${PN}.man" "doc/${PN}.1" || die
	mv "doc/${PN}rc.man" "doc/${PN}rc.5" || die
	doman "doc/${PN}.1" "doc/${PN}rc.5"
	einstalldocs
}

pkg_postinst() {
	ewarn "Note this part from man page: Security warning! Any exec command"
	ewarn "that uses the 'edit' flag will be a security hole. The user need"
	ewarn "only to enter text with a ';' in it, and they can run an"
	ewarn "arbitrary command after the semicolon!"
}