mldonkey-2.6.2.ebuild

mldonkey-2.6.2.ebuild (text/plain), 6.05 KB, created by Przemyslaw Maciag (RETIRED) on 2005-08-22 13:19:05 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/mldonkey/mldonkey-2.6.2.ebuild,v 1.1 2005/08/20 23:45:36 sekretarz Exp $

inherit eutils

IUSE="gtk gtk2 oldgtk guionly batch threads gd doc mozilla"

MOZVER="1.7"

DESCRIPTION="mldonkey is a new client to access the eDonkey network. It is written in Objective-Caml, and comes with its own GTK GUI, an HTTP interface and a telnet interface."
HOMEPAGE="http://www.nongnu.org/mldonkey/"
SRC_URI="http://savannah.nongnu.org/download/mldonkey/${P}.tar.bz2
	mozilla? ( http://www.informatik.uni-oldenburg.de/~dyna/${PN}/${MOZVER}/mldonkey_protocol_handler-${MOZVER}.xpi )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~ppc ~alpha ~ia64 ~amd64"

RDEPEND="dev-lang/perl
	oldgtk? ( =dev-ml/lablgtk-1.2.7* )
	!oldgtk? ( gtk2? ( >=gnome-base/librsvg-2.4.0 >=dev-ml/lablgtk-2.4 )
		!gtk2? ( gtk? ( =dev-ml/lablgtk-1.2.7* )
			guionly? ( =dev-ml/lablgtk-1.2.7* ) ) )
	gd? >=media-libs/gd-2.0.28"

DEPEND="${RDEPEND}
	>=sys-devel/autoconf-2.58
	!batch? >=dev-lang/ocaml-3.08.3
	batch? net-misc/wget"

MLUSER="p2p"

pkg_setup() {
	echo ""
	einfo "If the compile with gui fails, and you have updated ocaml"
	einfo "recently, you may have forgotten that you need to run"
	einfo "/usr/portage/dev-lang/ocaml/files/ocaml-rebuild.sh"
	einfo "to learn which ebuilds you need to recompile"
	einfo "each time you update ocaml to a different version"
	einfo "see the ocaml ebuild for details"
	echo ""

	local chosengui=0
	use gtk && chosengui=$[chosengui+1]
	use gtk2 && chosengui=$[chosengui+2]
	use oldgtk && chosengui=$[chosengui+4]

	# multiple gui chosen selection
	if [[ $chosengui == 1 ]]; then
		einfo "gtk gui will be installed"
	elif [[ $chosengui == 2 || $chosengui == 3 ]]; then
		einfo "gtk2 gui will be installed"
	elif [[ $chosengui == 4 ]]; then
		einfo "oldgtk gui will be installed"
	elif [[ $chosengui != 0 ]]; then
		ewarn "QAUTION! Multiple use flags for building mldonkey's gui"
		ewarn "was detected. Mldonkey may be build with only one gui type."
		ewarn "Emerge is going to choose a gui for you:"
		ewarn "oldgtk gui will be installed"
		ewarn "If you want to install a different gui type"
		ewarn "adjust mldonkey's USE flags to your needs"
		ebeep
		epause 5
	fi;

	# guionly version without gui flag
	if use guionly && !(use gtk2 || use gtk || use oldgtk); then
		ewarn "You choosed to install guionly mldonkey version"
		ewarn "but you haven't specified what type of gui you"
		ewarn "want (oldgtk, gtk or gtk2)."
		ewarn "Default gui type - gtk one - will be installed"
		ebeep
		epause 5
	fi

	# check is gtk2 gui was chosen
	# if so - was labgtk build with svg flag?
	if [[ $chosengui == 2 || $chosengui == 3 ]] && !(built_with_use dev-ml/lablgtk svg); then
		eerror "dev-ml/lablgtk must be built with the 'svg' USE flag to use the gtk2 gui"
		eerror "re-emerge lablgtk with svg USE flag of choose another gui type"
		die
	fi
}

src_unpack() {
	unpack ${P}.tar.bz2
}

src_compile() {
	export WANT_AUTOCONF=2.5
	cd ${S}/config
	autoconf

	# the dirs are not (yet) used, but it doesn't hurt to specify them anyway

	# batch 	Automatically download and build OCAML-3.08.3 for compiling itself
	# threads 	Enables multiple threads (TURN IT ON YES WILL YA?)
	# onlygui	Disable all nets support, build only chosen GUI

	if use oldgtk; then
		myconf="--enable-gui=oldgui"
	elif use gtk2; then
		myconf="--enable-gui=newgui2"
	elif use gtk || use guionly; then
		myconf="--enable-gui=newgui1"
	else
		myconf="--disable-gui"
	fi

	if use guionly; then
		myconf="${myconf} --disable-multinet --disable-donkey"
	fi

	cd ${S}
	econf \
		--sysconfdir=/etc/mldonkey \
		--sharedstatedir=/var/mldonkey \
		--localstatedir=/var/mldonkey \
		--enable-checks \
		`use_enable threads pthread` \
		`use_enable batch batch` \
		`use_enable gd` \
		${myconf} || die "Configure Failed!"

	export OCAMLRUNPARAM="l=256M"
	emake || die "Make Failed"

	if !(use guionly); then
		emake utils || die "make utils failed"
	fi;
}

src_install() {
	if !(use guionly); then
		dobin mlnet ed2k_hash get_range copysources make_torrent subconv
		dobin ${FILESDIR}/mldonkey

		insinto /etc/conf.d; newins ${FILESDIR}/mldonkey.confd mldonkey
		exeinto /etc/init.d; newexe ${FILESDIR}/mldonkey.initd mldonkey
	fi

	if (use gtk2 || use gtk || use oldgtk); then
		dobin mlgui mlguistarter mlchat mlim mlprogress

		domenu ${FILESDIR}/${PN}-gui.desktop
		doicon ${FILESDIR}/${PN}.png
	fi

	if use doc ; then
		cd ${S}/distrib
		dodoc ChangeLog *.txt
		dohtml *.html

		insinto /usr/share/doc/${PF}/scripts
		doins kill_mldonkey mldonkey_command mldonkey_previewer make_buginfo

		cd ${S}/docs
		dodoc *.txt *.tex *.pdf
		dohtml *.html

		cd ${S}/docs/developers
		dodoc *.txt *.tex

		cd ${S}/docs/images
		insinto /usr/share/doc/${PF}/html/images
		doins *
	fi

	if use mozilla; then
		insinto /usr/share/${PN}
		doins ${DISTFILES}/mldonkey_protocol_handler-${MOZVER}.xpi
	fi;
}

pkg_preinst() {
	if !(use guionly); then
		enewuser ${MLUSER} -1 /bin/bash /home/p2p users
	fi
}

pkg_postinst() {
	if !(use guionly); then
		echo
		einfo "Running \`mldonkey' will start the server inside ~/.mldonkey/"
		einfo "If you want to start mldonkey in a particular working directory,"
		einfo "use the \`mlnet' command."
		einfo "If you want to start mldonkey as a system service, use"
		einfo "the /etc/init.d/mldonkey script. To control bandwidth, use"
		einfo "the 'slow' and 'fast' arguments. Be sure to have a look at"
		einfo "/etc/conf.d/mldonkey also."
		echo
		einfo "Attention: 2.6 has changed the inifiles structure, so downgrading"
		einfo "will be problematic."
		einfo "User settings (admin) are transferred to users.ini from "
		einfo "downloads.ini"
		einfo "Old ini files are automatically converted to the new format"
		echo
	else
		echo
		einfo "Simply run mlgui to start the chosen modonkey gui."
		einfo "It puts its config files into ~/.mldonkey"
	fi

	if use mozilla; then
		echo
		einfo "xpi handler was placed in /usr/share/${PN} directory."
		einfo "Run it as root user and you can use ed2k links in your"
		einfo "favorite web browser (mozilla / firefox)."
	fi;
}