# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils qt3

MY_PN="${PN/-/_}"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="A Linux GUI for the iRiver iFP flash portable player based on QT"
HOMEPAGE="http://ifpgui.sourceforge.net"
SRC_URI="mirror://sourceforge/ifpgui/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="doc"

RDEPEND="dev-libs/libifp
	$(qt_min_version 3.3)
	>=dev-libs/libusb-0.1.0"
DEPEND="${RDEPEND}
	>=sys-apps/sed-4
	doc? (>=app-doc/doxygen-1.3.7)"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	unpack ${A}

	cd ${S}
	# these Makefiles causes me some strange problems
	# possible cause: there's no /usr/lib/qt3 directory
	# in gentoo
	rm Makefile src/Makefile

	epatch ${FILESDIR}/${PN}-doxyfile_fixes.patch
	# version number haven't changed in Doxygen file since
	# version 0.6.1 - better sed this, since it's very probable
	# that this is not going to be change in future releases
	sed -i -e '/PROJECT_NUMBER/ s/0.6.1/'${PV}'/' Doxyfile

	# we want to use system lib
	rm -rf src/libifp src/ifp.h
	epatch ${FILESDIR}/${PN}-use_system_libifp.patch
}

src_compile() {
	${QTDIR}/bin/qmake ${S}/src/src.pro \
		QMAKE_CXXFLAGS_RELEASE="${CXXFLAGS}" \
		QMAKE_RPATH= \
		|| die "qmake src.pro failed"

	${QTDIR}/bin/qmake ${S}/ifp_gui.pro \
		QMAKE_CXXFLAGS_RELEASE="${CXXFLAGS}" \
		QMAKE_RPATH= \
		|| die "qmake ifp_gui.pro failed"

	addwrite "${QTDIR}/etc/settings"

	emake || die "emake failed"
	
	use doc && cd ${S} && doxygen
}

src_install() {
	dobin src/${PN}
	dodoc README CHANGELOG COPYING

	use doc && dohtml html/*

	domenu ${FILESDIR}/${PN}.desktop
	doicon ${FILESDIR}/${PN}.png
}