Molden-6.5 ebuild

molden-6.5.ebuild (text/plain), 1.41 KB, created by Viktor Yu. Kovalskii on 2020-09-29 07:23:43 UTC

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit eutils fortran-2 flag-o-matic toolchain-funcs

DESCRIPTION="Display molecular density from GAMESS-UK, GAMESS-US, GAUSSIAN and Mopac/Ampac"
HOMEPAGE="http://www.cmbi.ru.nl/molden/"
SRC_URI="ftp://ftp.cmbi.ru.nl/pub/molgraph/${PN}/${PN}${PV}.tar.gz"

LICENSE="MOLDEN"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="opengl"

RDEPEND="
	x11-libs/libXmu
	virtual/glu
"
DEPEND="${RDEPEND}
	x11-misc/gccmakedep
	app-editors/vim"
	# vim provides ex, which the build system uses (surf/Makefile, at least)

S="${WORKDIR}/${PN}${PV}"

PATCHES=(
	"${FILESDIR}"/${PN}-6.5-ambfor.patch
	"${FILESDIR}"/${PN}-5.9-overflow.patch
	"${FILESDIR}"/${PN}-6.5-ldflags.patch
	"${FILESDIR}"/${PN}-6.5-implicit-dec.patch
)

src_prepare() {
	default
	sed \
		-e 's:makedepend:gccmakedep:g' \
		-i src/surf/Makefile || die
	sed 's:shell g77:shell $(FC):g' -i makefile || die
}

src_compile() {
	local args=()

	# Use -mieee on alpha, according to the Makefile
	use alpha && append-flags -mieee

	if [[ $(gcc-major-version) -eq 10 ]]; then
		append-flags -fallow-argument-mismatch
	fi

	args=(
		CC="$(tc-getCC) ${CFLAGS}"
		FC="$(tc-getFC)"
		LDR="$(tc-getFC)"
		FFLAGS="${FFLAGS}"
	)

	einfo "Building Molden..."
	emake -j1 "${args[@]}"
}

src_install() {
	dobin bin/${PN} bin/g${PN}

	dodoc HISTORY README REGISTER
	cd doc || die
	uncompress * && dodoc *
}