# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

CVS_MONTH="Jul"
CVS_YEAR="2005"
MY_P="tinyos"

inherit java-utils

DESCRIPTION="TinyOS JNI getenv support library"
HOMEPAGE="http://www.tinyos.net/"
SRC_URI="http://www.tinyos.net/dist-1.1.0/tinyos/source/${MY_P}-${PV}${CVS_MONTH}${CVS_YEAR}cvs.tar.gz"
LICENSE="Intel"
SLOT="1"
KEYWORDS="~x86"
IUSE="javacomm"
DEPEND=">=dev-java/ibm-jdk-bin-1.4.0
	dev-java/java-config"
RDEPEND=">=dev-java/ibm-jdk-bin-1.4.0"

S="${WORKDIR}/tinyos-1.x/tools/java/jni"

pkg_setup() {
	java-utils_setup-vm
	java-utils_ensure-vm-version-ge 1 4 0

	local vendor=`java-utils_get-vm-vendor`
	einfo "${vendor} vm detected."
	if ! [[ ${vendor} = "ibm-jdk-bin" ]]; then
		eerror "ibm-jdk-bin is required!"
		eerror "Please use java-config -S to set your system vm to a ibm-jdk."
		die "setup failed due to missing prerequisite: ibm-jdk-bin"
	fi

	if ! useq javacomm ; then
		eerror "javacomm is required! Add javacomm to your use flag then re-emerge ibm-jdk-bin."
		eerror "Then re-emerge this package."
		die "setup failed due to missing prerequisite: javacomm"
	fi
}


src_unpack() {
	unpack ${A}
	cd ${WORKDIR}
	mv ${MY_P}-${PV}${CVS_MONTH}${CVS_YEAR}cvs tinyos-1.x
}

src_compile() {
	# Quoting the Makefile:
	# The install rules assume that JNI libraries should be placed in .../jre/bin
	# This seems to be true on Windows, and IBM's Linux Java
	# It's not true for Sun's Linux Java (but we don't have javax.comm for that, so...)

	local JNI="$(java-config -O)/jre/bin"
	local JDK="$(java-config -O)"

	cd ${S}
	make -f Makefile.Linux "JDK=${JDK}" "JNI=${JNI}" clean all || die "Failed compiling libgetenv.so"
}

src_install() {
	local JNI="$(java-config -O)/jre/bin"
	cd ${S}
	dodir ${JNI}
	insinto ${JNI}
	doins libgetenv.so
}