liquidwar-5.6.5.ebuild

liquidwar-5.6.5.ebuild (text/plain), 1.58 KB, created by Khumba on 2020-09-20 08:27:52 UTC

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=6
inherit desktop

DESCRIPTION="Unique multiplayer wargame"
HOMEPAGE="https://ufoot.org/liquidwar/"
SRC_URI="https://ufoot.org/download/${PN}/v5/${PV}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc64 ~x86"
IUSE=""
RESTRICT="test"

RDEPEND=">=media-libs/allegro-4.2:0[X]"
DEPEND="${RDEPEND}"

src_prepare() {
	default

	eapply "${FILESDIR}"/${PN}-5.6.4-exec-stack.patch
	sed -i \
		-e 's:/games::' \
		-e '/^MANDIR/ s:=.*:= $(mandir)/man6:' \
		-e '/^PIXDIR/ s:=.*:= /usr/share/pixmaps:' \
		-e '/^DESKTOPDIR/ s:=.*:= /usr/share/applications/:' \
		-e '/^INFODIR/ s/=.*/= $(infodir)/' \
		-e '/^GAMEDIR/ s/exec_prefix/bindir/' \
		-e '/install/s:-s ::' \
		-e 's:$(DOCDIR)/txt:$(DOCDIR):g' \
		-e 's:$(GMAKE):$(MAKE):' \
		-e '/^DOCDIR/ s:=.*:= /usr/share/doc/$(PF):' Makefile.in \
		|| die 'sed Makefile.in failed'
	sed -i \
		-e '/^GAMEDIR/ s/$(exec_prefix)/@bindir@/' \
		-e 's:/games::' src/Makefile.in \
		|| die "sed src/Makefile.in failed"
	eapply "${FILESDIR}"/${PN}-5.6.5-underlink.patch
}

src_configure() {
	econf \
		--disable-doc-ps \
		--disable-doc-pdf \
		--disable-target-opt \
		$(use_enable x86 asm)
}

src_compile() {
	# skip build_doc target wrt bug 460344
	emake build_bin build_data
}

src_install() {
	emake DESTDIR="${D}" install_nolink
	einstalldocs
	rm -f "${ED}"/usr/share/doc/${PF}/COPYING
	# Provided desktop file is completely obsolete
	rm -f "${ED}"/usr/share/applications/liquidwar.desktop
	make_desktop_entry ${PN} "Liquid War" /usr/share/pixmaps/${PN}.xpm
}