proj-7.1.1.ebuild

proj-7.1.1.ebuild (text/plain), 1.51 KB, created by LE GARREC Vincent on 2020-09-16 08:48:35 UTC

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

DATA="${PN}-data-1.2.tar.gz"
DATUMGRID="${PN}-datumgrid-1.8.tar.gz"
EUROPE_DATUMGRID="${PN}-datumgrid-europe-1.6.tar.gz"

DESCRIPTION="PROJ coordinate transformation software"
HOMEPAGE="https://proj4.org/"
SRC_URI="
	https://download.osgeo.org/proj/${P}.tar.gz
	!legacy? ( tiff? ( https://download.osgeo.org/proj/${DATA} ) )
	legacy? (	https://download.osgeo.org/proj/${DATUMGRID}
				europe? ( https://download.osgeo.org/proj/${EUROPE_DATUMGRID} ) )
"

LICENSE="MIT"
SLOT="0/19"
KEYWORDS="amd64 ~arm arm64 ~ia64 ppc ppc64 ~s390 ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
IUSE="curl static-libs test +tiff legacy europe"
REQUIRED_USE="
	test? ( !europe )
	europe? ( legacy )
"

RESTRICT="!test? ( test )"

RDEPEND="
	dev-db/sqlite:3
	curl? ( net-misc/curl )
	tiff? ( media-libs/tiff )
"
DEPEND="${RDEPEND}"

src_unpack() {
	unpack ${P}.tar.gz
	cd "${S}"/data || die
	use legacy && (mv README README.DATA || die)
	use legacy && unpack ${DATUMGRID} && use europe && unpack ${EUROPE_DATUMGRID}
	use !legacy && use tiff && mkdir "${S}"/data2 && cd "${S}"/data2 && unpack ${DATA}
}

src_configure() {
	econf \
		$(use_with curl) \
		$(use_enable static-libs static) \
		$(use_enable tiff)
}

src_install() {
	default
	cd data || die
	use legacy && dodoc README.DATA
	find "${D}" -name '*.la' -type f -delete || die
	use !legacy && use tiff && cd ../data2 && dodoc README.DATA && insinto /usr/share/proj && doins -r *
}