# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit nsplugins toolchain-funcs multilib

DESCRIPTION="mplayer plug-in for Mozilla"
HOMEPAGE="http://mplayerplug-in.sourceforge.net/"
GECKO_SDK="gecko-sdk-i686-pc-linux-gnu-1.7.3.tar.gz"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
	x86? ( ftp://ftp.mozilla.org/pub/mozilla.org/mozilla/releases/mozilla1.7.3/${GECKO_SDK})"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

DEPEND="
	>=media-video/mplayer-1.0_pre5
	!x86? (net-libs/gecko-sdk)
	>=x11-libs/gtk+-2.2.0
	dev-libs/atk
	>=dev-libs/glib-2.2.0
	>=x11-libs/pango-1.2.1"

S=${WORKDIR}/${PN}

src_unpack() {
	unpack ${A} || die "Unpacking the source failed"
	cd ${S} || die "Could not change directory."
}

src_compile() {
	local myconf
	einfo "ACCEPT_KEYWORDS: ${ACCEPT_KEYWORDS}"
	if use x86; then
		einfo "Using i686 prebuilt gecko-sdk from mozilla.org"
		myconf="${myconf} --with-gecko-sdk=${WORKDIR}/gecko-sdk"
	else
		einfo "Using gecko-sdk installed on system"
		myconf="${myconf} --with-gecko-sdk=/usr/share/gecko-sdk/"
	fi
	myconf="${myconf} --enable-gtk2"
	econf ${myconf} || die
	emake || die
}

src_install() {
	exeinto /opt/netscape/plugins
	doexe mplayerplug-in*.so || die "plugin failed"
	inst_plugin /opt/netscape/plugins/mplayerplug-in.so
	inst_plugin /opt/netscape/plugins/mplayerplug-in-gmp.so
	inst_plugin /opt/netscape/plugins/mplayerplug-in-wmp.so
	inst_plugin /opt/netscape/plugins/mplayerplug-in-qt.so
	inst_plugin /opt/netscape/plugins/mplayerplug-in-rm.so

	# Install .xpt, bug #83162
	insinto /opt/netscape/plugins
	doins mplayerplug-in*.xpt
	inst_plugin /opt/netscape/plugins/mplayerplug-in.xpt
	inst_plugin /opt/netscape/plugins/mplayerplug-in-gmp.xpt
	inst_plugin /opt/netscape/plugins/mplayerplug-in-wmp.xpt
	inst_plugin /opt/netscape/plugins/mplayerplug-in-qt.xpt
	inst_plugin /opt/netscape/plugins/mplayerplug-in-rm.xpt

	insinto /etc
	doins mplayerplug-in.conf
	doins mplayerplug-in.types
	domo po/*.mo
	dodoc ChangeLog INSTALL README TODO DOCS/tech/*.txt
}