# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils fdo-mime

DESCRIPTION="Fyre is a tool for computational art based on a chaotic map"
SRC_URI="http://flapjack.navi.cx/releases/${PN}/${P}.tar.bz2"
HOMEPAGE="http://fyre.navi.cx/"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~x86"
IUSE="cluster openexr"

DEPEND="media-libs/libpng
	cluster? ( >=net-libs/gnet-2.0 )
	openexr? ( media-libs/openexr )
	dev-util/pkgconfig
	>=dev-libs/glib-2.0
	>=gnome-base/libglade-2.0
	>=x11-libs/gtk+-2.0"

src_unpack() {
	unpack ${A}
	cd ${S}

	# Patch the initscript to drop to nobody before running.
	epatch ${FILESDIR}/${PN}-1.0.0-initscript.diff
}

src_compile() {
	econf \
		--disable-dependency-tracking \
		$(use_enable cluster gnet) \
		$(use_enable openexr) \
		|| die "econf failed"

	emake || die "emake failed"
}

src_install() {
	make DESTDIR=${D} \
		update_xdgmime=/bin/true update_fdodesktop=/bin/true \
		install || die "install failed"
	dodoc AUTHORS ChangeLog README NEWS TODO

	if use cluster; then
		exeinto /etc/init.d
		newexe contrib/fyre.gentoo-initscript fyre
	fi
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
}