# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

DESCRIPTION="Modified openssh client, used by nxclient"
HOMEPAGE="http://www.nomachine.com/"
URI_BASE="http://www.nomachine.com/download/1.5.0/sources"
SRC_NXSSH="${PN}-${PV}-19.tar.gz"
SRC_NXCOMP="nxcomp-1.5.0-63.tar.gz"
SRC_URI="$URI_BASE/${SRC_NXSSH} $URI_BASE/${SRC_NXCOMP}"
LICENSE="as-is"
SLOT="0"
KEYWORDS="~x86 ~ppc"

# nxssh requires libcrypt, and nxclient is shipped with libcrypt.so.0.9.8,
# from openssl-0.9.8. However, gentoo has openssl-0.9.8 hard masked, latest
# stable version being openssl-0.9.7e-r1. As previous versions of nxssh
# only required openssl-0.9.7d-r1, that should work with nx-ssh-1.5.0 as well,
# but this isn't tested upstream. Please don't mark this package stable until
# openssl-0.9.8 is stable and the deps on this package is updated.
DEPEND="=net-misc/nx-x11-1.5*
	>=dev-libs/openssl-0.9.7d-r1
	>=sys-libs/glibc-2.3.3.20040420-r1
	>=sys-libs/zlib-1.2.1-r2
	tcpd? ( sys-apps/tcp-wrappers )
	pam? ( sys-libs/pam )"
IUSE="ipv6 pam tcpd"

S=${WORKDIR}/${PN}

src_unpack() {
	# we can't use ${A} because of bug #61977
	unpack ${SRC_NXSSH}
	unpack ${SRC_NXCOMP}

	cd ${S}
}

src_compile() {
	local myconf

	use tcpd || myconf="${myconf} --without-tcp-wrappers"
	use tcpd && myconf="${myconf} --with-tcp-wrappers"
	use pam  || myconf="${myconf} --without-pam"
	use pam  && myconf="${myconf} --with-pam"
	use ipv6 || myconf="${myconf} --with-ipv4-default"

	./configure \
		--prefix=/usr \
		--sysconfdir=/etc/ssh \
		--mandir=/usr/share/man \
		--libexecdir=/usr/lib/misc \
		--datadir=/usr/share/openssh \
		--disable-suid-ssh \
		--with-privsep-path=/var/empty \
		--with-privsep-user=sshd \
		--with-md5-passwords \
		--host=${CHOST} ${myconf} || die "bad configure"

	emake || die "compile problem"
}

src_install() {
	exeinto /usr/NX/bin
	doexe nxssh
}