# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_PN="${PN//x11/X11}"
DESCRIPTION="A special version of the X11 libraries supporting NX compression technology"
HOMEPAGE="http://www.nomachine.com/developers.php"
URI_BASE="http://www.nomachine.com/download/1.5.0/sources"
SRC_NX_X11="${MY_PN}-${PV}-15.tar.gz"
SRC_NXAGENT="nxagent-1.5.0-87.tar.gz"
SRC_NXAUTH="nxauth-1.5.0-1.tar.gz"
SRC_NXCOMP="nxcomp-1.5.0-63.tar.gz"
SRC_NXCOMPEXT="nxcompext-1.5.0-16.tar.gz"
SRC_NXVIEWER="nxviewer-1.5.0-14.tar.gz"
SRC_NXDESKTOP="nxdesktop-1.5.0-59.tar.gz"
SRC_URI="$URI_BASE/${SRC_NX_X11} $URI_BASE/${SRC_NXAGENT} $URI_BASE/${SRC_NXAUTH} $URI_BASE/${SRC_NXCOMP} $URI_BASE/${SRC_NXCOMPEXT} $URI_BASE/${SRC_NXVIEWER} $URI_BASE/${SRC_NXDESKTOP}"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~ppc"
IUSE=""
#RESTRICT="nostrip"
DEPEND="virtual/x11
	>=media-libs/jpeg-6b-r3
	>=media-libs/libpng-1.2.8
	>=sys-libs/zlib-1.2.1-r2
	>=sys-devel/gcc-3.2.3-r2
	>=sys-libs/glibc-2.3.2-r3"
#RDEPEND=""
S=${WORKDIR}/${MY_PN}

src_unpack() {
	# we can't use ${A} because of bug #61977
	unpack ${SRC_NX_X11}
	unpack ${SRC_NXAGENT}
	unpack ${SRC_NXAUTH}
	unpack ${SRC_NXCOMP}
	unpack ${SRC_NXCOMPEXT}
	unpack ${SRC_NXVIEWER}
	unpack ${SRC_NXDESKTOP}

	cd ${S}
	epatch ${FILESDIR}/${PN}-1.4.0.xprint.patch
}

src_compile() {
	emake World || die "unable to build nx-11"

	cd ../nxviewer
	xmkmf || die "unable to create makefile for nxviewer"
	emake World || die "unable to make nxviewer"

	cd ../nxdesktop
	./configure --prefix=/usr/NX --mandir=/usr/share/man --sharedir=/usr/share || die "Unable to configure nxdesktop"
	emake || die "Unable to build nxdesktop"

}

src_install() {
	into /usr/NX

	dobin programs/Xserver/nxagent
	dobin programs/nxauth/nxauth
	dobin ../nxviewer/nxviewer/nxviewer
	dobin ../nxviewer/nxpasswd/nxpasswd
	dobin ../nxdesktop/nxdesktop

	pushd lib/X11/
	dolib libX11.so.6.2
	dolib libX11.so
	popd

	pushd lib/Xext/
	dolib libXext.so.6.4
	dolib libXext.so
	popd

	pushd lib/Xrender/
	dolib libXrender.so.1.2
	dolib libXrender.so
	popd

	pushd ../nxcomp/
	dolib libXcomp.so.1.4.0
	dolib libXcomp.so
	popd

	pushd ../nxcompext/
	dolib libXcompext.so.1.5.0
	dolib libXcompext.so
	popd

	preplib /usr/NX

	insinto /usr/X11R6/include
	doins ../nxcomp/NX.h

	dodir /var/lib/nxserver

}