# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI="7"

inherit autotools eutils multilib-minimal

if [[ ${PV} == *9999 ]] ; then
	EGIT_REPO_URI="https://github.com/periscop/cloog"
	inherit git-r3
else
	KEYWORDS="~alpha amd64 arm ~arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~s390 sparc x86"
	SRC_URI="https://github.com/periscop/cloog/archive/${P}.tar.gz"
fi

DESCRIPTION="A loop generator for scanning polyhedra"
HOMEPAGE="https://github.com/periscop/cloog"

LICENSE="LGPL-2.1"
SLOT="0/4"
IUSE="static-libs"

RDEPEND=">=dev-libs/gmp-6.0.0[${MULTILIB_USEDEP}]
	>=dev-libs/isl-0.15:0=[${MULTILIB_USEDEP}]"
DEPEND="${DEPEND}
	virtual/pkgconfig"

S="${WORKDIR}/cloog-${P}"

DOCS=( README )

src_prepare() {
	if [[ ${PV} == "9999" ]] ; then
		./get_submodules.sh
		eautoreconf -i
	else
		# texi2dvi -I ./doc --pdf doc/cloog.texi -o doc/cloog.pdf
		# TeX neither supports -recorder nor outputs \openout lines in its log file
		eapply "${FILESDIR}/${P}-notexi.patch"
		AT_NO_RECURSIVE=yes eautoreconf -i
		# m4/ax_create_pkgconfig_info.m4 includes LDFLAGS
		# sed to avoid eautoreconf
		sed -i -e '/Libs:/s:@LDFLAGS@ ::' configure || die
	fi

	# Make sure we always use the system isl.
	rm -rf isl
	default
}

multilib_src_configure() {

	ECONF_SOURCE="${S}" econf \
		--with-gmp=system \
		--with-isl=system \
		--with-osl=no \
		$(use_enable static-libs static)
}

# The default src_test() fails, so we'll just run these directly
multilib_src_test() {
	echo ">>> Test phase [check]: ${CATEGORY}/${PF}"
	emake -j1 check
}

multilib_src_install_all() {
	einstalldocs
	if ! use static-libs; then
		find "${D}" -name '*.la' -type f -delete || die
	fi
}