mplayerplug-in-3.05.ebuild

mplayerplug-in-3.05.ebuild (text/plain), 2.38 KB, created by Chandler Carruth on 2005-08-06 21:43:53 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit nsplugins toolchain-funcs multilib

DESCRIPTION="mplayer plug-in for Mozilla"
HOMEPAGE="http://mplayerplug-in.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 -hppa ~ia64 ppc ~sparc ~x86"
IUSE="gtk2 windowsmedia quicktime realmedia googlemedia"

DEPEND="
	>=media-video/mplayer-1.0_pre5
	>=net-libs/gecko-sdk-1.7.8
	gtk2? (
		>=x11-libs/gtk+-2.2.0
		dev-libs/atk
		>=dev-libs/glib-2.2.0
		>=x11-libs/pango-1.2.1 )
	!gtk2? (
		=x11-libs/gtk+-1.2*
		=dev-libs/glib-1.2* )"

S=${WORKDIR}/${PN}

src_compile() {
	local myconf
	myconf="${myconf} --with-gecko-sdk=/usr/$(get_libdir)/gecko-sdk"
	if use gtk2; then
		einfo Configuring to build using gtk2
		myconf="${myconf} --enable-gtk2"
	else
		einfo Configuring to build using gtk1
		myconf="${myconf} --disable-gtk2 --enable-gtk1"
	fi
	econf ${myconf} \
		$(use-enable windowsmedia wmp) \
		$(use-enable quicktime qt) \
		$(use-enable realmedia rm) \
		$(use-enable googlemedia gmp) \
		|| die
	emake || die
}

src_install() {
	exeinto /opt/netscape/plugins
	insinto /opt/netscape/plugins
	
	doexe mplayerplug-in.so || die "plugin failed"
	inst_plugin /opt/netscape/plugins/mplayerplug-in.so

	doins mplayerplug-in.xpt
	inst_plugin /opt/netscape/plugins/mplayerplug-in.xpt

	if use windowsmedia; then
		doexe mplayerplug-in-wmp.so || die "plugin failed"
		inst_plugin /opt/netscape/plugins/mplayerplug-in-wmp.so

		doins mplayerplug-in-wmp.xpt
		inst_plugin /opt/netscape/plugins/mplayerplug-in-wmp.xpt
	fi

	if use quicktime; then
		doexe mplayerplug-in-qt.so || die "plugin failed"
		inst_plugin /opt/netscape/plugins/mplayerplug-in-qt.so

		doins mplayerplug-in-qt.xpt
		inst_plugin /opt/netscape/plugins/mplayerplug-in-qt.xpt
	fi

	if use realmedia; then
		doexe mplayerplug-in-rm.so || die "plugin failed"
		inst_plugin /opt/netscape/plugins/mplayerplug-in-rm.so

		doins mplayerplug-in-rm.xpt
		inst_plugin /opt/netscape/plugins/mplayerplug-in-rm.xpt
	fi

	if use googlemedia; then
		doexe mplayerplug-in-gmp.so || die "plugin failed"
		inst_plugin /opt/netscape/plugins/mplayerplug-in-gmp.so

		doins mplayerplug-in-gmp.xpt
		inst_plugin /opt/netscape/plugins/mplayerplug-in-gmp.xpt
	fi

	insinto /etc
	doins mplayerplug-in.conf

	dodoc ChangeLog INSTALL README TODO DOCS/tech/*.txt
}