new ebuild

libxmlbird-1.2.11.ebuild (text/plain), 1.15 KB, created by Michal Plichta on 2020-08-03 20:02:37 UTC

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( python3_{6,7,8} )
inherit python-any-r1 vala toolchain-funcs

SRC_URI="https://birdfont.org/xmlbird-releases/${P}.tar.xz"
RESTRICT="primaryuri"
KEYWORDS="~amd64 ~x86"

DESCRIPTION="XML parser written in Vala"
HOMEPAGE="https://birdfont.org/xmlbird.php"

LICENSE="LGPL-3"
SLOT="0"
IUSE=""

RDEPEND=""
DEPEND="
        ${RDEPEND}
        ${PYTHON_DEPS}
        $(vala_depend)
"

pkg_setup() {
        python-any-r1_pkg_setup
}

src_prepare() {
        default
        vala_src_prepare
}

src_configure() {
        "${PYTHON}" ./configure \
                --prefix "${EPREFIX}/usr" \
                --cc "$(tc-getCC)" \
                --valac "${VALAC}" \
                --cflags "${CFLAGS}" \
                --ldflags "${LDFLAGS}" \
                --libdir "/$(get_libdir)" \
                || die
}

src_compile() {
        "${PYTHON}" ./build.py || die
}

src_install() {
        "${PYTHON}" ./install.py \
                --dest "${D}" \
                || die
        einstalldocs
}