mplayerplug-in-3.05.ebuild

mplayerplug-in-3.05.ebuild (text/plain), 2.23 KB, created by Gergan Penkov on 2005-08-06 10:54:50 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit nsplugins toolchain-funcs multilib

DESCRIPTION="mplayer plug-in for Mozilla"
HOMEPAGE="http://mplayerplug-in.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 -hppa ~ia64 ppc ~sparc ~x86"
IUSE="gtk2 firefox"

DEPEND="
	>=media-video/mplayer-1.0_pre5
	!firefox? ( >=www-client/mozilla-1.7.10 )
	firefox? ( >=www-client/mozilla-firefox-1.0.6 )
	gtk2? (
		>=x11-libs/gtk+-2.2.0
		dev-libs/atk
		>=dev-libs/glib-2.2.0
		>=x11-libs/pango-1.2.1 )
	!gtk2? (
		=x11-libs/gtk+-1.2*
		=dev-libs/glib-1.2* )"

S=${WORKDIR}/${PN}

src_unpack() {
	unpack ${A} || die "Unpacking the source failed"
	cd ${S} || die "Could not change directory."
	epatch ${FILESDIR}/${PN}-rpath.patch
}

src_compile() {
	local myconf
	if use firefox; then
		einfo Configuring to build using mozilla-firefox
		myconf="${myconf} --with-gecko-sdk=/usr/$(get_libdir)/mozilla-firefox"
	else
		einfo Configuring to build using mozilla
		myconf="${myconf} --with-gecko-sdk=/usr/$(get_libdir)/mozilla"
	fi
	if use gtk2; then
		einfo Configuring to build using gtk2
		myconf="${myconf} --enable-gtk2"
	else
		einfo Configuring to build using gtk1
		myconf="${myconf} --disable-gtk2 --enable-gtk1"
	fi
	econf ${myconf} || die
	emake || die
}

src_install() {
	exeinto /opt/netscape/plugins
	doexe mplayerplug-in*.so || die "plugin failed"
	inst_plugin /opt/netscape/plugins/mplayerplug-in.so
	inst_plugin /opt/netscape/plugins/mplayerplug-in-gmp.so
	inst_plugin /opt/netscape/plugins/mplayerplug-in-wmp.so
	inst_plugin /opt/netscape/plugins/mplayerplug-in-qt.so
	inst_plugin /opt/netscape/plugins/mplayerplug-in-rm.so

	# Install .xpt, bug #83162
	insinto /opt/netscape/plugins
	doins mplayerplug-in*.xpt
	inst_plugin /opt/netscape/plugins/mplayerplug-in.xpt
	inst_plugin /opt/netscape/plugins/mplayerplug-in-gmp.xpt
	inst_plugin /opt/netscape/plugins/mplayerplug-in-wmp.xpt
	inst_plugin /opt/netscape/plugins/mplayerplug-in-qt.xpt
	inst_plugin /opt/netscape/plugins/mplayerplug-in-rm.xpt

	insinto /etc
	doins mplayerplug-in.conf
	doins mplayerplug-in.types
	domo po/*.mo
	dodoc ChangeLog INSTALL README TODO DOCS/tech/*.txt
}